websocket-obs-java/build.gradle at develop · B1llstar/websocket-obs-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
    id 'maven'
    id 'signing'
    id 'org.unbroken-dome.test-sets' version '3.0.1'
}

def isRelease = System.getenv('IS_RELEASE') == 'YES'

if (isRelease) {
    println("THIS IS A RELEASE BUILD! Artifacts will be staged on maven central.")
}

group = 'net.twasi'
version = rootProject.file('VERSION').text.trim() + (isRelease ? '' : '-SNAPSHOT')
archivesBaseName = rootProject.name

java.sourceCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenLocal()
    jcenter()
    maven {
        url = uri('https://repo.maven.apache.org/maven2/')
    }
}

dependencies {
    implementation 'org.eclipse.jetty.websocket:websocket-client:9.4.8.v20171121'
    implementation 'com.google.code.gson:gson:2.8.2'
    implementation 'org.slf4j:slf4j-api:1.7.30'
    implementation 'org.slf4j:slf4j-simple:1.7.30'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.0.0'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.0.0'
    testImplementation 'org.assertj:assertj-core:3.18.1'
}

java {
    withSourcesJar()
    // withJavadocJar()
}

testSets {
    integrationTest
}

test {
    useJUnitPlatform()
}

integrationTest {
    useJUnitPlatform()
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    def signingKey = System.getenv('PGP_KEY') ? System.getenv('PGP_KEY').replace("\\n", "\n") : ''
    def signingPassword = System.getenv('PGP_PSW')

    useInMemoryPgpKeys(signingKey, signingPassword)

    if (signingKey != '') {
        sign configurations.archives
    }
}

def ossrhUsername = System.getenv('OSSRH_USERNAME')
def ossrhPassword = System.getenv('OSSRH_PASSWORD')

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'websocket-obs-java'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'Library to connect to the OBS WebSocket interface.'
                url 'https://github.com/Twasi/obs-websocket-java'

                scm {
                    connection 'scm:git:git://github.com/Twasi/obs-websocket-java.git'
                    developerConnection 'scm:git:git@github.com:Twasi/obs-websocket-java.git'
                    url 'https://github.com/Twasi/obs-websocket-java'
                }

                licenses {
                    license {
                        name 'MIT'
                        url 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        name 'Lars Bärtschi'
                        email 'lars@twasi.net'
                    }
                    developer {
                        name 'Merlin Westphal'
                        email 'merlin@twasi.net'
                    }
                }
            }
        }
    }
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}