feat(wrapperModules.claude-code): init (#181)

Author: vinnymeller

flake.nix

@@ -9,9 +9,15 @@
         if inputs.pkgs.stdenv.hostPlatform.system or null == system then
           inputs.pkgs
         else if inputs.nixpkgs.legacyPackages.${system} or null != null then
-          inputs.nixpkgs.legacyPackages.${system}
+          import inputs.nixpkgs {
+            inherit system;
+            config.allowUnfree = true;
+          }
         else
-          import (inputs.pkgs.path or inputs.nixpkgs or <nixpkgs>) { inherit system; };
+          import (inputs.pkgs.path or inputs.nixpkgs or <nixpkgs>) {
+            inherit system;
+            config.allowUnfree = true;
+          };
       lib = inputs.pkgs.lib or inputs.nixpkgs.lib or (import "${inputs.nixpkgs or <nixpkgs>}/lib");
       forAllSystems = lib.genAttrs lib.platforms.all;
     in

maintainers/default.nix

@@ -11,4 +11,9 @@
     github = "rencire";
     githubId = 546296;
   };
+  vinnymeller = {
+    name = "Vinny Meller";
+    github = "vinnymeller";
+    githubId = 19894025;
+  };
 }

wrapperModules/c/claude-code/check.nix

@@ -0,0 +1,21 @@
+{
+  pkgs,
+  self,
+}:
+let
+  claudeCodeWrapped = self.wrappedModules.claude-code.wrap {
+    inherit pkgs;
+
+    mcpConfig = {
+      nixos = {
+        command = "${pkgs.mcp-nixos}/bin/mcp-nixos";
+        type = "stdio";
+      };
+    };
+    strictMcpConfig = true;
+  };
+in
+pkgs.runCommand "claude-code-test" { } ''
+  "${claudeCodeWrapped}/bin/claude" mcp get nixos
+  touch $out
+''

wrapperModules/c/claude-code/module.nix

@@ -0,0 +1,90 @@
+{
+  config,
+  lib,
+  wlib,
+  pkgs,
+  ...
+}:
+let
+  jsonFmt = pkgs.formats.json { };
+in
+{
+  imports = [ wlib.modules.default ];
+
+  options = {
+
+    settings = lib.mkOption {
+      type = jsonFmt.type;
+      default = { };
+      description = ''
+        Claude Code settings
+
+        These settings will override local, project, and user scoped settings.
+
+        See <https://code.claude.com/docs/en/settings>
+      '';
+      example = {
+        includeCoAuthoredBy = false;
+        permissions = {
+          deny = [
+            "Bash(sudo:*)"
+            "Bash(rm -rf:*)"
+          ];
+        };
+      };
+    };
+
+    mcpConfig = lib.mkOption {
+      type = lib.jsonFmt.type;
+      default = { };
+      description = ''
+        MCP Server configuration
+
+        Exclude the top-level `mcpServers` key from the configuration as it is automatically handled.
+
+        See <https://code.claude.com/docs/en/mcp>
+      '';
+      example = {
+        nixos = {
+          command = "${pkgs.mcp-nixos}/bin/mcp-nixos";
+          type = "stdio";
+        };
+      };
+    };
+
+    strictMcpConfig = lib.mkOption {
+      type = lib.types.bool;
+      default = false;
+      description = ''
+        Whether to enable the `--strict-mcp-config` flag for Claude Code.
+
+        When enabled, Claude will only use the MCP servers provided by the `mcpConfig` option.
+
+        If disabled, Claude may use MCP servers defined elsewhere (e.g., user or project scoped configurations).
+      '';
+    };
+
+  };
+
+  config = {
+    package = lib.mkDefault pkgs.claude-code;
+    unsetVar = lib.mkDefault [
+      "DEV"
+      # the vast majority of users will want to authenticate with their claude account and not an API key
+      "ANTHROPIC_API_KEY"
+    ];
+    envDefault = lib.mkDefault {
+      DISABLE_AUTOUPDATER = "1";
+      CLAUDE_CODE_DISABLE_NONESSENTIAL_TRAFFIC = "1";
+      DISABLE_NON_ESSENTIAL_MODEL_CALLS = "1";
+      DISABLE_TELEMETRY = "1";
+      DISABLE_INSTALLATION_CHECKS = "1";
+    };
+    flags = {
+      "--mcp-config" = jsonFmt.generate "claude-mcp-config.json" { mcpServers = config.settings; };
+      "--strict-mcp-config" = config.strictMcpConfig;
+      "--settings" = jsonFmt.generate "claude-settings.json" config.settings;
+    };
+    meta.maintainers = [ wlib.maintainers.vinnymeller ];
+  };
+}