CBA_A3/addons/xeh/fnc_postInit_unscheduled.sqf at d6cbc0f4351f21206fad6a140be22a2a906771b4 · CBATeam/CBA_A3 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
#include "script_component.hpp"
/* ----------------------------------------------------------------------------
Function: CBA_fnc_postInit_unscheduled

Description:
    Occurs once per mission after objects and functions are initialized.
    Internal use only.

Parameters:
    None

Returns:
    None

Author:
    commy2
---------------------------------------------------------------------------- */

XEH_LOG("XEH: PostInit started. " + PFORMAT_9("MISSIONINIT",missionName,missionVersion,worldName,isMultiplayer,isServer,isDedicated,CBA_isHeadlessClient,hasInterface,didJIP));

// fix CBA_missionTime being -1 on (non-JIP) clients at mission start.
if (CBA_missionTime == -1) then {
    CBA_missionTime = 0;
};

// call PostInit events
{
    if (_x select 1 == "postInit") then {
        [] call (_x select 2);
    };
} forEach GVAR(allEventHandlers);

// do InitPost
{
    _x params ["_this"];

    {
        [_this] call _x;
    } forEach (_this getVariable QGVAR(initPost));
} forEach GVAR(initPostStack);

GVAR(initPostStack) = nil;

#ifdef DEBUG_MODE_FULL
    diag_log text format ["isScheduled = %1", call CBA_fnc_isScheduled];
#endif

SLX_XEH_MACHINE set [8, true]; // PostInit passed

XEH_LOG("XEH: PostInit finished.");