CommandAliases/build.gradle at 1.21/dev · FlashyReese/CommandAliases · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
plugins {
	id 'fabric-loom' version '1.11-SNAPSHOT'
	id 'maven-publish'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

base {
    archivesName = project.archives_base_name
}

version = "${project.mod_version}+mc${project.minecraft_version}-${getVersionMetadata()}"
group = project.maven_group

repositories {
	maven {
		name = "Lucko"
		url 'https://oss.sonatype.org/content/repositories/snapshots'
	}
	maven {
		name = "Modrinth"
		url = "https://api.modrinth.com/maven"
		content {
			includeGroup "maven.modrinth"
		}
	}
	maven {
		url "https://maven.nucleoid.xyz/"
		name "Nucleoid"
	}
	mavenCentral()
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// Permissions API
	include(modImplementation("me.lucko:fabric-permissions-api:0.5.0"))

	// Placeholders API
	modImplementation include("eu.pb4:placeholder-api:2.8.0+1.21.9")

	// LevelDB
	include(implementation("org.iq80.leveldb:leveldb:0.12"))
	include(implementation("org.iq80.leveldb:leveldb-api:0.12"))

	// MySQL
	include(implementation("com.mysql:mysql-connector-j:9.4.0"))

	// Redis
	include(implementation("redis.clients:jedis:6.2.0"))
	//include(implementation("org.apache.commons:commons-pool2:2.12.1"))

	// Parsing Libraries
	include(implementation("com.fasterxml.jackson.dataformat:jackson-dataformat-toml:2.20.0"))
	include(implementation("com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.20.0"))
	//include(implementation("org.yaml:snakeyaml:2.5"))
	include(implementation("com.fasterxml.jackson.core:jackson-core:2.20.0"))
	include(implementation("com.fasterxml.jackson.core:jackson-databind:2.20.0"))
	include(implementation("com.fasterxml.jackson.core:jackson-annotations:3.0-rc5"))

	// Math Evaluator
	include(implementation("com.fathzer:javaluator:3.0.6"))

	//modRuntimeOnly "maven.modrinth:lazydfu:0.1.3"
	//modRuntimeOnly "maven.modrinth:sodium:mc1.19-0.4.2"
	//modRuntimeOnly "maven.modrinth:lithium:mc1.19-0.8.0"
	//modRuntimeOnly "maven.modrinth:phosphor:mc1.19.x-0.8.1"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 21
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE.txt")
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			artifactId = project.base.archivesName.get()
			from components.java
		}
	}

	// select the repositories you want to publish to
	repositories {
		// uncomment to publish to the local maven
		maven {
			name = "FlashyReeseReleases"
			url = "https://maven.flashyreese.me/releases"
			credentials {
				username = System.getenv("MAVEN_USERNAME")
				password = System.getenv("MAVEN_PASSWORD")
			}
		}
		maven {
			name = "FlashyReeseSnapshots"
			url = "https://maven.flashyreese.me/snapshots"
			credentials {
				username = System.getenv("MAVEN_USERNAME")
				password = System.getenv("MAVEN_PASSWORD")
			}
		}
	}
}

static def getVersionMetadata() {
	def build_id = System.getenv("GITHUB_RUN_NUMBER")

	// CI builds only
	if (build_id != null) {
		return "build.${build_id}"
	}

	// No tracking information could be found about the build
	return "unknown"
}