build.gradle

/*
 * This file is part of VelocityTitle(https://github.com/RedStarMC/VelocityTitle).
 *
 * Copyright (C) RedStarMC and contributors.
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 ******************************************************************************/

import org.apache.tools.ant.filters.ReplaceTokens

plugins{
    id 'java-library'
}

def now_version = "0.2.0"

allprojects {
    apply {
        plugin 'java-library'
    }

    group = 'top.redstarmc.plugin.velocitytitle'

    version = now_version

    repositories {
        mavenCentral()  //Maven 存储库
        maven { url 'https://repo.codemc.io/repository/maven-releases/' }
    }

    dependencies {
        compileOnly 'org.jetbrains:annotations:23.0.0'
        implementation 'com.moandjiezana.toml:toml4j:0.7.2'
        implementation "net.kyori:adventure-api:4.25.0"
    }


    // 编译 固定 UTF-8 编码
    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
    }
    // Javadoc 固定 UTF-8 编码
    tasks.withType(Javadoc).tap {
        configureEach {
            options.encoding = "UTF-8"
        }
    }

    // 固定使用 Java21
    java {
        toolchain.languageVersion.set(JavaLanguageVersion.of(21))
    }

    processResources {
        // 匹配所有资源文件
        filesMatching('**/*') {
            filter(ReplaceTokens, tokens: [encoding: 'UTF-8'])
            filter { Object line ->
                line.toString().replace('@VERSION@', project.version)
            }
        }
        filteringCharset = 'UTF-8'
    }

}

subprojects {
    // 1. 配置原始 Jar 任务（包含自身代码和core模块代码）
    tasks.withType(Jar).tap {
        configureEach {
            group = 'build'
            destinationDirectory.set(rootProject.file("${rootProject.rootDir}/build/jars"))
            archiveClassifier.set('original') // 明确标记为原始 JAR

            // 包含自身代码、资源和core模块代码
            from sourceSets.main.output
            // 仅对velocity和spigot模块添加core代码
            if (project.name in ['velocity', 'spigot']) {
                from project(':core').sourceSets.main.output
            }
        }
    }

    // 2. 配置包含依赖的 JAR 任务（xxx.jar）
    tasks.register('jarWithDependencies', Jar) {
        group = 'build'
        destinationDirectory.set(rootProject.file("${rootProject.rootDir}/build/jars"))
        archiveBaseName.set(jar.archiveBaseName)
        archiveClassifier.set('')

        from {
            sourceSets.main.output // 包含当前模块的代码和资源
            // 仅对velocity和spigot模块添加core代码
            if (project.name in ['velocity', 'spigot']) {
                project(':core').sourceSets.main.output
            }
        }

        // 收集外部依赖（排除项目内的 original.jar）
        from {
            configurations.runtimeClasspath.collect { file ->
                // 排除项目内生成的 original.jar（避免重复打包）
                if (file.name.endsWith("-original.jar")) {
                    null // 跳过 original.jar
                } else {
                    file.isDirectory() ? file : zipTree(file)
                }
            }.findAll { it != null } // 过滤掉 null 值
        }

        exclude 'META-INF/*', '*.MF'
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }

    // 3. 确保 build 任务同时执行两个 JAR 任务
    tasks.named('build') {
        dependsOn(tasks.named('jar'), tasks.named('jarWithDependencies'))
    }
}

tasks.register('createAllJar', Jar) {
    group = 'build'

    archiveBaseName.set('VelocityTitle')
    archiveVersion.set(now_version)

    // 收集所有子模块的类文件和资源文件
    from {
        subprojects.collect { subproject ->
            [subproject.file("build/classes/java/main"),
             subproject.file("build/resources/main")].findAll { it != null && it.exists() }
        }
    }

    // 收集所有子模块的依赖
    from {
        subprojects.collectMany { subproject ->
            subproject.configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
        }
    }

    exclude 'META-INF/*', '*.MF'
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    destinationDirectory.set(rootProject.file("${rootProject.rootDir}/build/jars"))

    // 添加对子模块构建任务的依赖
    subprojects.each { project ->
        dependsOn project.tasks.named('build')
    }
}

tasks.named('build') {
    finalizedBy('createAllJar')
}