cabal-hoogle/flake.nix at main · YourFin/cabal-hoogle · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs =
    inputs@{ nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        compilers = [
          "ghc94"
          "ghc96"
          "ghc98"
          "ghc910"
          "ghc912"
        ];
        defaultCompiler = "ghc912";

        mkShell =
          compiler:
          pkgs.mkShell {
            buildInputs = with pkgs; [
              zlib.dev
            ];
            packages =
              with pkgs;
              [
                cabal-install
                haskell.compiler.${compiler}
                ormolu
                miniserve
              ]
              ++ (
                with haskell.packages.${compiler};
                (lib.lists.optional (
                  !(builtins.elem compiler [
                    "ghc96"
                  ])
                ) haskell-language-server)
                ++ (lib.lists.optional (
                  !(builtins.elem compiler [
                    "ghc912"
                  ])
                ) cabal-fmt)
                ++ [
                  ghcid
                ]
              );
            shellHook = ''
              export CABAL_DIR=$(pwd)/.cabal
              export CABAL_CONFIG=$(pwd)/.cabal/config
            '';
          };
      in
      {
        devShells = {
          default = mkShell defaultCompiler;
        }
        // builtins.listToAttrs (
          builtins.map (compiler: {
            name = compiler;
            value = mkShell compiler;
          }) compilers
        );
      }
    );
}