Merge pull request #1 from babbel/initial

Initial version

Author: Jan Sebastian Siwy

.github/dependabot.yml

@@ -0,0 +1,10 @@
+version: 2
+
+updates:
+- package-ecosystem: github-actions
+  directory: /
+  schedule:
+    interval: weekly
+    day: sunday
+    time: "11:00"
+    timezone: Europe/Berlin

.github/workflows/validate.yml

@@ -0,0 +1,20 @@
+name: Validate
+
+on: push
+
+env:
+  AWS_REGION: local
+
+jobs:
+  validate:
+    runs-on: ubuntu-20.04
+    defaults:
+      run:
+        working-directory: _test
+    steps:
+      - uses: actions/checkout@v2.4.0
+      - uses: hashicorp/setup-terraform@v1.3.2
+        with:
+          terraform_version: 0.15.5
+      - run: terraform init
+      - run: terraform validate

.gitignore

@@ -0,0 +1,2 @@
+/_test/.terraform
+/_test/.terraform.lock.hcl

CHANGELOG.md

@@ -0,0 +1,5 @@
+# Changelog
+
+## v1.0.0
+
+- [Initial version](https://github.com/babbel/terraform-aws-acm/pull/1)

LICENSE

@@ -0,0 +1,7 @@
+Copyright 2022 Babbel GmbH
+
+Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

README.md

@@ -1,2 +1,26 @@
-# terraform-aws-acm
-Terraform module creating an ACM certificate
+# AWS Certificate Manager (ACM) Terraform module creating and validating an ACM certificate
+
+Terraform module which creates a ACM certificate in one region and validates it using Route53 DNS.
+
+This is a simplified version of the [`terraform-aws-modules/acm/aws`](https://registry.terraform.io/modules/terraform-aws-modules/acm/aws) module which is waiting before returning certificate ARN as the `this_acm_certificate_arn` output until the validation is completed (returning `aws_acm_certificate_validation#certificate_arn` instead of `aws_acm_certificate#arn`). This is necessary for a seamless `terraform apply` incl. the resources using that certificate.
+
+## Usage
+
+```tf
+module "acm" {
+  source  = "babbel/acm/aws"
+  version = "~> 1.0"
+
+  primary_domain_name = "example.com"
+
+  domain_names_to_zone_ids = {
+    "example.com"     = "XYZXYZXYZXYZXYZ"
+    "www.example.com" = "YZXYZXYZXYZXYZX"
+  }
+
+  tags = {
+    app  = "some-service"
+    env  = "production"
+  }
+}
+```

_test/main.tf

@@ -0,0 +1,15 @@
+module "acm" {
+  source  = "./.."
+
+  primary_domain_name = "example.com"
+
+  domain_names_to_zone_ids = {
+    "example.com"     = "XYZXYZXYZXYZXYZ"
+    "www.example.com" = "YZXYZXYZXYZXYZX"
+  }
+
+  tags = {
+    app  = "some-service"
+    env  = "production"
+  }
+}

main.tf

@@ -0,0 +1,34 @@
+resource "aws_acm_certificate" "this" {
+  domain_name               = var.primary_domain_name
+  subject_alternative_names = setsubtract(keys(var.domain_names_to_zone_ids), [var.primary_domain_name])
+  validation_method         = "DNS"
+
+  tags = var.tags
+
+  lifecycle {
+    create_before_destroy = true
+  }
+}
+
+resource "aws_route53_record" "validation" {
+  for_each = {
+    for dvo in aws_acm_certificate.this.domain_validation_options : dvo.domain_name => {
+      name   = dvo.resource_record_name
+      record = dvo.resource_record_value
+      type   = dvo.resource_record_type
+    }
+  }
+
+  zone_id = var.domain_names_to_zone_ids[each.key]
+  name    = each.value.name
+  type    = each.value.type
+  ttl     = 60
+
+  records = [each.value.record]
+}
+
+resource "aws_acm_certificate_validation" "this" {
+  certificate_arn = aws_acm_certificate.this.arn
+
+  validation_record_fqdns = [for record in aws_route53_record.validation : record.fqdn]
+}

outputs.tf

@@ -0,0 +1,4 @@
+output "acm_certificate_arn" {
+  description = "The ARN of the certificate"
+  value       = aws_acm_certificate_validation.this.certificate_arn
+}

variables.tf

@@ -0,0 +1,15 @@
+variable "primary_domain_name" {
+  description = "A domain name for which the certificate should be issued"
+  type        = string
+}
+
+variable "domain_names_to_zone_ids" {
+  description = "Map of domain names (incl. `var.primary_domain_name`) to Route53 hosted zone IDs"
+  type        = map(string)
+}
+
+variable "tags" {
+  description = "A mapping of tags to assign to the resource"
+  type        = map(string)
+  default     = {}
+}