Initial commit

Author: Igor Barchenkov

.formatter.exs

@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["mix.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]

.gitignore

@@ -0,0 +1,24 @@
+# The directory Mix will write compiled artifacts to.
+/_build/
+
+# If you run "mix test --cover", coverage assets end up here.
+/cover/
+
+# The directory Mix downloads your dependencies sources to.
+/deps/
+
+# Where 3rd-party dependencies like ExDoc output generated docs.
+/doc/
+
+# Ignore .fetch files in case you like to edit your project deps locally.
+/.fetch
+
+# If the VM crashes, it generates a dump, let's ignore it too.
+erl_crash.dump
+
+# Also ignore archive artifacts (built via "mix archive.build").
+*.ez
+
+# Ignore package tarball (built via "mix hex.build").
+cubecto-*.tar
+

README.md

@@ -0,0 +1,80 @@
+# Cubecto
+
+Cubecto adds a [`Postgrex.Extension`][1] and [`Ecto.Type`][2] definitions
+for the datatypes defined in the [`cube`][3] PostgreSQL module.
+
+## Installation
+
+**Add the package to your Mixfile**
+
+```elixir
+defp deps do
+  [{:cubecto, "~> 0.1.0"}]
+end
+```
+
+
+**Add Cubecto.Extension to the Postgrex types file somewhere in lib/my_app/**
+
+```elixir
+Postgrex.Types.define(
+  MyApp.PostgrexTypes,
+  [Cubecto.Extension] ++ Ecto.Adapters.Postgres.extensions()
+)
+```
+
+**Configure Repo to use custom Postgrex types in config/config.exs**
+
+```elixir
+config :my_app, MyApp.Repo,
+  types: MyApp.PostgrexTypes
+```
+
+**Create the cube extension in the database**
+
+```elixir
+defmodule MyApp.Repo.Migrations.CreateCubeExtension do
+  use Ecto.Migration
+
+  def change do
+    execute(
+      "CREATE EXTENSION IF NOT EXISTS cube",
+      "DROP EXTENSION IF EXISTS cube"
+    )
+  end
+end
+```
+
+## Usage
+
+**Add a column with the cube datatype to a table**
+
+```elixir
+defmodule MyApp.Repo.Migrations.CreateUser do
+  use Ecto.Migration
+
+  def change do
+    create table("users") do
+      add :cube, :cube
+      # other fields
+    end
+  end
+end
+```
+
+**Use Cubecto.Type for the cube field in an Ecto.Schema module**
+
+```elixir
+defmodule MyApp.Accounts.User do
+  use Ecto.Schema
+
+  schema "users" do
+    field :cube, Cubecto.Type
+    # other fields
+  end
+end
+```
+
+[1]: http://hexdocs.pm/postgrex/Postgrex.Extension.html
+[2]: http://hexdocs.pm/ecto/Ecto.Type.html
+[3]: https://www.postgresql.org/docs/current/static/cube.html

config/config.exs

@@ -0,0 +1,3 @@
+use Mix.Config
+
+import_config "#{Mix.env}.exs"

config/dev.exs

@@ -0,0 +1 @@
+use Mix.Config

config/prod.exs

@@ -0,0 +1 @@
+use Mix.Config

config/test.exs

@@ -0,0 +1,11 @@
+use Mix.Config
+
+config :cubecto, Cubecto.Test.Repo,
+  database: "cubecto_test",
+  username: "postgres",
+  password: "postgres",
+  hostname: "localhost",
+  adapter: Ecto.Adapters.Postgres,
+  types: Cubecto.Test.PostgrexTypes
+
+config :logger, level: :warn

lib/cubecto/extension.ex

@@ -0,0 +1,38 @@
+defmodule Cubecto.Extension do
+  @moduledoc false
+  @behaviour Postgrex.Extension
+
+  @impl true
+  def init(opts) do
+    Keyword.get(opts, :decode_copy, :copy)
+  end
+
+  @impl true
+  def matching(_), do: [type: "cube"]
+
+  @impl true
+  def format(_), do: :text
+
+  @impl true
+  def encode(_) do
+    quote do
+      bin when is_binary(bin) ->
+        [<<byte_size(bin)::signed-size(32)>> | bin]
+    end
+  end
+
+  @impl true
+  def decode(:reference) do
+    quote do
+      <<len::signed-size(32), bin::binary-size(len)>> ->
+        bin
+    end
+  end
+
+  def decode(:copy) do
+    quote do
+      <<len::signed-size(32), bin::binary-size(len)>> ->
+        :binary.copy(bin)
+    end
+  end
+end

lib/cubecto/type.ex

@@ -0,0 +1,44 @@
+defmodule Cubecto.Type do
+  @moduledoc false
+  @behaviour Ecto.Type
+
+  @impl true
+  def type, do: :cube
+
+  @impl true
+  def cast(list) when is_list(list) do
+    {:ok, list}
+  end
+
+  def cast(_), do: :error
+
+  @impl true
+  def load(string) do
+    list =
+      string
+      |> String.trim_leading("(")
+      |> String.trim_trailing(")")
+      |> String.split(", ")
+      |> Enum.map(&parse_value/1)
+
+    {:ok, list}
+  end
+
+  @impl true
+  def dump(list) when is_list(list) do
+    list =
+      list
+      |> Enum.map(&to_string/1)
+      |> Enum.join(", ")
+
+    {:ok, list}
+  end
+
+  def dump(_), do: :error
+
+  defp parse_value(val) do
+    {float, _} = Float.parse(val)
+    int = trunc(float)
+    if float == int, do: int, else: float
+  end
+end

mix.exs

@@ -0,0 +1,47 @@
+defmodule Cubecto.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :cubecto,
+      version: "0.1.0",
+      elixir: "~> 1.5",
+      start_permanent: Mix.env() == :prod,
+      elixirc_paths: elixirc_paths(Mix.env()),
+      deps: deps(),
+      docs: docs()
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  defp elixirc_paths(:test), do: ["lib", "test/support"]
+  defp elixirc_paths(_), do: ["lib"]
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:postgrex, ">= 0.13.2"},
+      {:ecto, ">= 2.1.0"},
+      {:ex_doc, "~> 0.18.0", only: :dev, runtime: false}
+    ]
+  end
+
+  defp docs do
+    [
+      main: "readme",
+      extras: extras()
+    ]
+  end
+
+  defp extras do
+    [
+      "README.md"
+    ]
+  end
+end