Initial commit

Author: debasishg

.gitignore

@@ -0,0 +1,3 @@
+_build/
+_opam/
+lib/model/tradeioml.code-workspace

bin/dune

@@ -0,0 +1,4 @@
+(executable
+ (public_name tradeioml)
+ (name main)
+ (libraries model repository))

bin/main.ml

@@ -0,0 +1 @@
+let () = print_endline "Hello, World!"

dune-project

@@ -0,0 +1,26 @@
+(lang dune 3.11)
+
+(name tradeioml)
+
+(generate_opam_files true)
+
+(source
+ (github username/reponame))
+
+(authors "Author Name")
+
+(maintainers "Maintainer Name")
+
+(license LICENSE)
+
+(documentation https://url/to/documentation)
+
+(package
+ (name tradeioml)
+ (synopsis "A short synopsis")
+ (description "A longer description")
+ (depends ocaml dune)
+ (tags
+  (topics "to describe" your project)))
+
+; See the complete stanza docs at https://dune.readthedocs.io/en/stable/dune-files.html#dune-project

lib/model/account.ml

@@ -0,0 +1,97 @@
+open Base 
+open CalendarLib
+open Calendar
+open Accountid
+open Account_sig
+open Common
+
+module Account : Account_sig = struct
+  (* implementation of an account *)
+  
+  (* hidden implementation for the base parts of an account *)
+  type account_base = {
+    no: Accountno.t;
+    name: Accountname.t;
+    date_of_open: CalendarLib.Calendar.t;
+    date_of_close: CalendarLib.Calendar.t option;
+  }
+  
+  (* the abstract representation of the account *)
+  type t = {
+    base: account_base;
+    account_type: Common.account_type;
+  }
+  
+  (* the concrete representations of account no and account name *)
+  (* hidden as part of the account representation *)
+  type account_no = Accountno.t
+  type account_name = Accountname.t
+
+  let build_account_base no name date_of_open date_of_close = 
+    {
+      no;
+      name;
+      date_of_open;
+      date_of_close
+    }
+
+  let validator_account_open_date =
+    let open Tvalidator in
+    TradingValidator.date_in_future "Cannot be in future"
+
+  let validate_base ~no ~name ~account_open_date ~account_close_date = 
+    let open Validator in
+    let valid = build build_account_base
+    |> keep no
+    |> keep name
+    |> validate account_open_date validator_account_open_date 
+    |> keep account_close_date in
+    match valid with
+    | Ok base -> Ok base
+    | Error e -> Error e
+
+  let create_trading_account ~no ~name ~trading_currency ~account_open_date = 
+    let valid = validate_base ~no ~name ~account_open_date ~account_close_date:None in
+    match valid with
+    | Ok base -> Ok { base; account_type = Trading trading_currency }
+    | Error e -> Error e 
+
+  let create_settlement_account ~no ~name ~settlement_currency ~account_open_date = 
+    let valid = validate_base ~no ~name ~account_open_date ~account_close_date:None in
+    match valid with
+    | Ok base -> Ok { base; account_type = Settlement settlement_currency }
+    | Error e -> Error e 
+  
+  let create_both_account ~no ~name ~trading_currency ~settlement_currency ~account_open_date = 
+    let valid = validate_base ~no ~name ~account_open_date ~account_close_date:None in
+    match valid with
+    | Ok base -> Ok { base; account_type = Both (trading_currency, settlement_currency) }
+    | Error e -> Error e 
+  
+  let validate_close ~account: t ~date_of_close = match t.base.date_of_close with 
+    | Some _ -> Error "Account is already closed"
+    | None ->  match compare t.base.date_of_open date_of_close with
+      | 0 -> Error "Account open and close date cannot be the same"
+      | 1 -> Error "Account open date cannot be after close date"
+      | _ -> Ok t
+  
+  let close ~account: t ~date_of_close =
+    let open Result in
+    validate_close ~account: t ~date_of_close >>= fun _ ->
+    Ok { 
+      t with base = { 
+        t.base with date_of_close = Some date_of_close 
+      } 
+    }
+
+  let get_account_type t = t.account_type
+  
+  let get_account_no t = t.base.no 
+  
+  let get_account_name t = t.base.name 
+  
+  let get_trading_and_settlement_currency = function
+    | { base = _ ; account_type = Trading trading_currency } -> (Some trading_currency, None)
+    | { base = _ ; account_type = Settlement settlement_currency } -> (None, Some settlement_currency)
+    | { base = _ ; account_type = Both (trading_currency, settlement_currency) } -> (Some trading_currency, Some settlement_currency)
+end  

lib/model/account_sig.ml

@@ -0,0 +1,36 @@
+open Common
+open Validator
+
+module type Account_sig = sig
+  (* abstract types *)
+  type t
+  type account_no
+  type account_name
+  
+  (* smart constructor to create a validated trading account *)
+  val create_trading_account: 
+    no: account_no -> name: account_name -> trading_currency: currency -> account_open_date: CalendarLib.Calendar.t -> (t, string) validator_result
+
+  (* smart constructor to create a validated settlement account *)
+  val create_settlement_account: 
+    no: account_no -> name: account_name -> settlement_currency: currency -> account_open_date: CalendarLib.Calendar.t -> (t, string) validator_result
+  
+  (* smart constructor to create a validated trading and settlement account *)
+  val create_both_account: 
+    no: account_no -> name: account_name -> trading_currency: currency -> settlement_currency: currency -> account_open_date: CalendarLib.Calendar.t -> (t, string) validator_result
+  
+  (* close an account *)
+  val close: account: t -> date_of_close: CalendarLib.Calendar.t -> (t, string) Result.t
+  
+  (* get the account type *)
+  val get_account_type: t -> Common.account_type
+  
+  (* get the trading and settlement currency *)
+  val get_trading_and_settlement_currency: t -> currency option * currency option
+  
+  (* get the account number *)
+  val get_account_no: t -> account_no 
+  
+  (* get the account name *)
+  val get_account_name: t -> account_name 
+end

lib/model/accountid.ml

@@ -0,0 +1,31 @@
+open Base
+open Id
+
+(* Implementing newtypes for accounts *)
+(* Use [of_string] constructor to construct a validated account no *)
+
+(* account number and validation *)
+module Accountno = struct
+  include String_id
+
+  let validate = 
+    let open Validator in
+    (string_has_max_length 12 "Too long")
+    |> compose
+      (string_has_min_length 3 "Too short")
+
+  let of_string x = validate x
+
+end
+
+(* account name and validation *)
+module Accountname = struct
+  include String_id
+
+  let validate = 
+    let open Validator in
+    string_is_not_empty "Empty"
+
+  let of_string x = validate x
+
+end

lib/model/common.ml

@@ -0,0 +1,8 @@
+(* some sample currencies for the time being *)
+type currency = USD | JPY | INR | GBP
+
+(* account_type will be trading, settlement or both *)
+type account_type = 
+  | Trading of currency           (* with trading currency *)
+  | Settlement of currency        (* with settlement currency *)
+  | Both of currency * currency   (* with trading and settlement currency *)

lib/model/dune

@@ -0,0 +1,3 @@
+(library
+ (name model)
+ (libraries base calendar unix str validator))

lib/model/id.ml

@@ -0,0 +1,17 @@
+module type ID = sig
+  type t
+
+  val to_string : t -> string
+  val of_string : string -> t
+  val ( = ) : t -> t -> bool
+
+end
+
+module String_id : ID = struct
+  type t = string
+
+  let to_string x = x
+  let of_string x = x
+  let ( = ) = String.equal
+
+end