migrate RCTAppState away from main thread initialization (#49476)

Summary:
Pull Request resolved: #49476

changelog: [internal]

Introduce RCTInitialAppStateProxy to access app initial state in thread safe way.

Reviewed By: javache

Differential Revision: D69745459

fbshipit-source-id: f88a04774e064bf13904183aa3334f93cbcc5283

Author: sammy-SC

packages/react-native/React/Base/UIKitProxies/RCTInitialAppStateProxy.h

@@ -0,0 +1,26 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <UIKit/UIKit.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface RCTInitialAppStateProxy : NSObject
+
++ (instancetype)sharedInstance;
+
+/*
+ * Property to access initial application state.
+ * Thread safe.
+ */
+@property (nonatomic, readonly) UIApplicationState initialAppState;
+
+- (void)recordAppState;
+
+@end
+
+NS_ASSUME_NONNULL_END

packages/react-native/React/Base/UIKitProxies/RCTInitialAppStateProxy.mm

@@ -0,0 +1,54 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTInitialAppStateProxy.h"
+#import <React/RCTUtils.h>
+#import <mutex>
+
+#import <React/RCTConstants.h>
+
+@implementation RCTInitialAppStateProxy {
+  BOOL _hasRecordedInitialAppState;
+  UIApplicationState _initialAppState;
+  std::mutex _mutex;
+}
+
++ (instancetype)sharedInstance
+{
+  static RCTInitialAppStateProxy *sharedInstance = nil;
+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    sharedInstance = [RCTInitialAppStateProxy new];
+  });
+  return sharedInstance;
+}
+
+- (UIApplicationState)initialAppState
+{
+  {
+    std::lock_guard<std::mutex> lock(_mutex);
+    if (_hasRecordedInitialAppState) {
+      return _initialAppState;
+    }
+  }
+
+  __block UIApplicationState initialAppState;
+  RCTUnsafeExecuteOnMainQueueSync(^{
+    initialAppState = [UIApplication sharedApplication].applicationState;
+  });
+
+  return initialAppState;
+}
+
+- (void)recordAppState
+{
+  std::lock_guard<std::mutex> lock(_mutex);
+  _hasRecordedInitialAppState = YES;
+  _initialAppState = [UIApplication sharedApplication].applicationState;
+}
+
+@end

packages/react-native/React/Base/UIKitProxies/RCTInitializeUIKitProxies.mm

@@ -6,6 +6,7 @@
  */
 
 #import "RCTInitializeUIKitProxies.h"
+#import "RCTInitialAppStateProxy.h"
 #import "RCTTraitCollectionProxy.h"
 #import "RCTWindowSafeAreaProxy.h"
 
@@ -15,5 +16,6 @@ void RCTInitializeUIKitProxies(void)
   dispatch_once(&onceToken, ^{
     [[RCTWindowSafeAreaProxy sharedInstance] startObservingSafeArea];
     [[RCTTraitCollectionProxy sharedInstance] startObservingTraitCollection];
+    [[RCTInitialAppStateProxy sharedInstance] recordAppState];
   });
 }

packages/react-native/React/CoreModules/RCTAppState.mm

@@ -11,6 +11,8 @@
 #import <React/RCTAssert.h>
 #import <React/RCTBridge.h>
 #import <React/RCTEventDispatcherProtocol.h>
+
+#import <React/RCTInitialAppStateProxy.h>
 #import <React/RCTUtils.h>
 
 #import "CoreModulesPlugins.h"
@@ -31,7 +33,7 @@
     return @"extension";
   }
 
-  return states[@(RCTSharedApplication().applicationState)] ?: @"unknown";
+  return states[@([RCTInitialAppStateProxy sharedInstance].initialAppState)] ?: @"unknown";
 }
 
 @interface RCTAppState () <NativeAppStateSpec>
@@ -45,7 +47,7 @@ @implementation RCTAppState {
 
 + (BOOL)requiresMainQueueSetup
 {
-  return YES;
+  return NO;
 }
 
 - (dispatch_queue_t)methodQueue
@@ -60,14 +62,9 @@ - (dispatch_queue_t)methodQueue
 
 - (facebook::react::ModuleConstants<JS::NativeAppState::Constants>)getConstants
 {
-  __block facebook::react::ModuleConstants<JS::NativeAppState::Constants> constants;
-  RCTUnsafeExecuteOnMainQueueSync(^{
-    constants = facebook::react::typedConstants<JS::NativeAppState::Constants>({
-        .initialAppState = RCTCurrentAppState(),
-    });
+  return facebook::react::typedConstants<JS::NativeAppState::Constants>({
+      .initialAppState = RCTCurrentAppState(),
   });
-
-  return constants;
 }
 
 #pragma mark - Lifecycle