veshell/devenv.nix at 88b086e5e8c53345cdc7e0448c318a9282b45543 · free-explorers/veshell · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
{ pkgs, lib, config, inputs, ... }:
let
 flutterHash = "sha256-s5T16+cMmL2ustJQjwFbfS8G+/TJW/WCEF1IO4WgbXQ=";
 flutterEngineHash = "sha256-XNZGEFE7ryNhA9Fc33n0v/uq7+IjdDDAMpqEVECRxws=";
in
let
  # Parse Flutter version from Cargo metadata
  cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
  flutterVersion = cargoToml.package.metadata.flutter_version;

  # Get Flutter from GitHub
  flutter = pkgs.flutter.overrideAttrs (oldAttrs: {
    src = pkgs.fetchFromGitHub {
      owner = "flutter";
      repo = "flutter";
      rev = flutterVersion;
      sha256 = flutterHash;
    };
    version = flutterVersion;
  });

  # Parse Flutter engine revision from Flutter
  engineRevisionFile = "${flutter}/bin/internal/engine.version";
  engineRevision = if builtins.pathExists engineRevisionFile
    then  lib.strings.removeSuffix "\n" (builtins.readFile engineRevisionFile)
    else "stable";

  # Get Flutter Engine from GitHub
  flutterEngine = pkgs.stdenv.mkDerivation rec {
    pname = "flutter-engine";
    version = engineRevision;

    src = pkgs.fetchurl {
      name = "flutter-engine-${version}.tar.gz";
      url = "https://github.com/meta-flutter/flutter-engine/releases/download/linux-engine-sdk-debug-x86_64-${version}/linux-engine-sdk-debug-x86_64-${version}.tar.gz";
      sha256 = flutterEngineHash;
    };

    nativeBuildInputs = with pkgs; [gnutar gzip];

    unpackPhase = ''
      runHook preUnpack
      mkdir -p $out
      tar -xzf $src
      mv flutter/engine/src/out/linux_debug_x64/engine-sdk/* $out/
      runHook postUnpack
    '';

    meta = with lib; {
      description = "Flutter engine libraries for Linux";
      homepage = "https://flutter.dev";
      license = licenses.bsd3;
      platforms = platforms.linux;
    };
  };
in
{
  packages = with pkgs; [
    clang
    cmake
    ninja
    pkg-config
    rustc
    cargo
    rustfmt
    clippy
    rust-analyzer
    gtk3
    sysprof
    libsysprof-capture
    pcre2
    openssl
    systemd
    seatd
    unzip
    jq
    git
    libxkbcommon libinput libgbm
    xwayland
    pulseaudio
  ];

  env = {
    RUST_BACKTRACE = "1";
    SKIP_FLUTTER_ENGINE_DOWNLOAD = "1";
    FLUTTER_PATH = flutter;
    FLUTTER_ENGINE_PATH = flutterEngine;
    LIBCLANG_PATH = "${pkgs.libclang.lib}/lib";
    LD_LIBRARY_PATH = "${pkgs.wayland}/lib:${pkgs.pulseaudio}/lib";
  };

  languages.dart = {
    enable = true;
    package = flutter;
  };

  enterShell = ''
    echo "=== Flutter Installation ==="

    # Symlink Flutter SDK
    if [ -d ".flutter_sdk" ] && [ ! -L ".flutter_sdk" ]; then
      echo "Removing existing .flutter_sdk directory..."
      rm -rf .flutter_sdk
    fi
    echo "Linking Flutter SDK..."
    ln -sfn ${flutter} .flutter_sdk

    # Symlink Flutter Engine
    echo "Linking Flutter Engine..."
    mkdir -p extra/third_party/flutter_engine/debug
    ln -sf "${flutterEngine}/lib/libflutter_engine.so" extra/third_party/flutter_engine/debug/libflutter_engine.so
    ln -sf "${flutterEngine}/include/flutter_embedder.h" extra/third_party/flutter_engine/flutter_embedder.h

    echo "=== Version Information ==="
    echo "Flutter version: $(${flutter}/bin/flutter --version --machine | jq -r '.flutterVersion')"
    echo "Dart version: $(${flutter}/bin/flutter --version --machine | jq -r '.dartSdkVersion')"
    echo "Engine revision: $(${flutter}/bin/flutter --version --machine | jq -r '.engineRevision')"
    echo "Channel: $(${flutter}/bin/flutter --version --machine | jq -r '.channel')"
  '';
}