C#: Add various extension related classes to the QL library.

Author: michaelnebel

csharp/ql/lib/semmle/code/csharp/Callable.qll

@@ -221,6 +221,23 @@ class Callable extends Parameterizable, ExprOrStmtParent, @callable {
 
   /** Gets a `Call` that has this callable as a target. */
   Call getACall() { this = result.getTarget() }
+
+  /** Holds if this callable is declared in an extension type. */
+  predicate isInExtension() { this.getDeclaringType() instanceof ExtensionType }
+}
+
+/**
+ * A callable that is declared as an extension.
+ *
+ * Either an extension method (`ExtensionMethod`), an extension operator
+ * (`ExtensionOperator`) or an extension accessor (`ExtensionAccessor`).
+ */
+abstract class ExtensionCallable extends Callable {
+  /** Gets the type being extended by this method. */
+  pragma[noinline]
+  Type getExtendedType() { result = this.getDeclaringType().(ExtensionType).getExtendedType() }
+
+  override string getAPrimaryQlClass() { result = "ExtensionCallable" }
 }
 
 /**
@@ -267,8 +284,11 @@ class Method extends Callable, Virtualizable, Attributable, @method {
 
   override Location getALocation() { method_location(this.getUnboundDeclaration(), result) }
 
+  /** Holds if this method is a classic extension method. */
+  predicate isClassicExtensionMethod() { this.getParameter(0).hasExtensionMethodModifier() }
+
   /** Holds if this method is an extension method. */
-  predicate isExtensionMethod() { this.getParameter(0).hasExtensionMethodModifier() }
+  predicate isExtensionMethod() { this.isClassicExtensionMethod() or this.isInExtension() }
 
   /** Gets the type of the `params` parameter of this method, if any. */
   Type getParamsType() {
@@ -296,24 +316,46 @@ class Method extends Callable, Virtualizable, Attributable, @method {
 }
 
 /**
- * An extension method, for example
+ * An extension method.
+ *
+ * Either a classic extension method (`ClassicExtensionMethod`) or an extension
+ * type extension method (`ExtensionTypeExtensionMethod`).
+ */
+abstract class ExtensionMethod extends ExtensionCallable, Method {
+  override string getAPrimaryQlClass() { result = "ExtensionMethod" }
+}
+
+/**
+ *  An extension method, for example
  *
  * ```csharp
  * static bool IsDefined(this Widget w) {
  *   ...
  * }
  * ```
  */
-class ExtensionMethod extends Method {
-  ExtensionMethod() { this.isExtensionMethod() }
-
-  override predicate isStatic() { any() }
+class ClassicExtensionMethod extends ExtensionMethod {
+  ClassicExtensionMethod() { this.isClassicExtensionMethod() }
 
-  /** Gets the type being extended by this method. */
   pragma[noinline]
-  Type getExtendedType() { result = this.getParameter(0).getType() }
+  override Type getExtendedType() { result = this.getParameter(0).getType() }
 
-  override string getAPrimaryQlClass() { result = "ExtensionMethod" }
+  override predicate isStatic() { any() }
+}
+
+/**
+ * An extension method declared in an extension type, for example `IsNullOrEmpty` in
+ *
+ * ```csharp
+ * static class MyExtensions {
+ *   extension(string s) {
+ *     public bool IsNullOrEmpty() { ... }
+ *   }
+ * }
+ * ```
+ */
+class ExtensionTypeExtensionMethod extends ExtensionMethod {
+  ExtensionTypeExtensionMethod() { this.isInExtension() }
 }
 
 /**
@@ -536,6 +578,20 @@ class RecordCloneMethod extends Method {
   }
 }
 
+/**
+ * An extension operator, for example `*` in
+ * ```csharp
+ * static class MyExtensions {
+ *   extension(string s) {
+ *     public static string operator *(int s1, string s2) { ... }
+ *   }
+ * }
+ * ```
+ */
+class ExtensionOperator extends ExtensionCallable, Operator {
+  ExtensionOperator() { this.isInExtension() }
+}
+
 /**
  * A user-defined unary operator - an operator taking one operand.
  *

csharp/ql/lib/semmle/code/csharp/Member.qll

@@ -469,7 +469,7 @@ class Virtualizable extends Overridable, Member, @virtualizable {
 
 /**
  * A parameterizable declaration. Either a callable (`Callable`), a delegate
- * type (`DelegateType`), or an indexer (`Indexer`).
+ * type (`DelegateType`), an indexer (`Indexer`) or an extension block (`ExtensionType`).
  */
 class Parameterizable extends Declaration, @parameterizable {
   /** Gets raw parameter `i`, including the `this` parameter at index 0. */

csharp/ql/lib/semmle/code/csharp/Property.qll

@@ -260,6 +260,20 @@ class Property extends DeclarationWithGetSetAccessors, @property {
   override string getAPrimaryQlClass() { result = "Property" }
 }
 
+/**
+ * An extension property, for example `FirstChar` in
+ * ```csharp
+ * static class MyExtensions {
+ *  extension(string s) {
+ *    public char FirstChar { get { ... } }
+ *  }
+ * }
+ * ```
+ */
+class ExtensionProperty extends Property {
+  ExtensionProperty() { this.getDeclaringType() instanceof ExtensionType }
+}
+
 /**
  * An indexer, for example `string this[int i]` on line 2 in
  *
@@ -413,6 +427,21 @@ class Accessor extends Callable, Modifiable, Attributable, Overridable, @callabl
   override string toString() { result = this.getName() }
 }
 
+/**
+ *  An extension accessor. Either a getter (`Getter`), a setter (`Setter`) of an
+ *  extension property, for example `get` in
+ * ```csharp
+ * static class MyExtensions {
+ *  extension(string s) {
+ *    public char FirstChar { get { ... } }
+ *  }
+ * }
+ * ```
+ */
+class ExtensionAccessor extends ExtensionCallable, Accessor {
+  ExtensionAccessor() { this.getDeclaringType() instanceof ExtensionType }
+}
+
 /**
  * A `get` accessor, for example `get { return p; }` in
  *

csharp/ql/lib/semmle/code/csharp/Type.qll

@@ -17,7 +17,8 @@ private import semmle.code.csharp.frameworks.system.runtime.CompilerServices
  *
  * Either a value or reference type (`ValueOrRefType`), the `void` type (`VoidType`),
  * a pointer type (`PointerType`), the arglist type (`ArglistType`), an unknown
- * type (`UnknownType`), or a type parameter (`TypeParameter`).
+ * type (`UnknownType`), a type parameter (`TypeParameter`) or
+ * an extension type (`ExtensionType`).
  */
 class Type extends Member, TypeContainer, @type {
   /** Gets the name of this type without additional syntax such as `[]` or `*`. */
@@ -1326,3 +1327,28 @@ class TypeMention extends @type_mention {
   /** Gets the location of this type mention. */
   Location getLocation() { type_mention_location(this, result) }
 }
+
+/**
+ * A type extension declaration, for example `extensions(string s) { ... }` in
+ * ```csharp
+ * static class MyExtensions {
+ *  extensions(string s) { ... }
+ * ```
+ */
+class ExtensionType extends Parameterizable, @extension_type {
+  /**
+   * Gets the receiver parameter of this extension type, if any.
+   */
+  Parameter getReceiverParameter() { params(result, _, _, 0, _, this, _) }
+
+  /**
+   * Holds if this extension type has a receiver parameter.
+   */
+  predicate hasReceiverParameter() { exists(this.getReceiverParameter()) }
+
+  /** Gets the type being extended by this extension type. */
+  // TODO: This doesn't handle the case where there is no parameter.
+  Type getExtendedType() { result = this.getReceiverParameter().getType() }
+
+  override string getAPrimaryQlClass() { result = "ExtensionType" }
+}

csharp/ql/lib/semmle/code/csharp/exprs/Call.qll

@@ -479,6 +479,29 @@ class OperatorCall extends Call, LateBindableExpr, @operator_invocation_expr {
   override string getAPrimaryQlClass() { result = "OperatorCall" }
 }
 
+/**
+ * A call to an extension operator, for example `3 * s` on
+ * line 9 in
+ * ```csharp
+ * static class MyExtensions {
+ *   extension(string s) {
+ *     public static string operator *(int i, string s) { ... }
+ *   }
+ * }
+ *
+ * class A {
+ *   string M(string s) {
+ *     return 3 * s;
+ *   }
+ * }
+ * ```
+ */
+class ExtensionOperatorCall extends OperatorCall {
+  ExtensionOperatorCall() { this.getTarget() instanceof ExtensionOperator }
+
+  override string getAPrimaryQlClass() { result = "ExtensionOperatorCall" }
+}
+
 /**
  * A call to a user-defined mutator operator, for example `a++` on
  * line 7 in
@@ -577,8 +600,8 @@ class FunctionPointerCall extends DelegateLikeCall, @function_pointer_invocation
 
 /**
  * A call to an accessor. Either a property accessor call (`PropertyCall`),
- * an indexer accessor call (`IndexerCall`), or an event accessor call
- * (`EventCall`).
+ * an indexer accessor call (`IndexerCall`), an event accessor call
+ * (`EventCall`) or an extension accessor call (`ExtensionAccessorCall`).
  */
 class AccessorCall extends Call, QualifiableExpr, @call_access_expr {
   override Accessor getTarget() { none() }
@@ -588,6 +611,35 @@ class AccessorCall extends Call, QualifiableExpr, @call_access_expr {
   override Accessor getARuntimeTarget() { result = Call.super.getARuntimeTarget() }
 }
 
+/**
+ * A direct call to an extension accessor, for example `MyExtensions.get_FirstChar(s)`
+ * in
+ * ```csharp
+ * static class MyExtensions {
+ *   extension(string s) {
+ *     public char FirstChar { get { ... } }
+ *   }
+ * }
+ *
+ * class A {
+ *   char M(string s) {
+ *     return MyExtensions.get_FirstChar(s);
+ *   }
+ * }
+ * ```
+ */
+class ExtensionAccessorCall extends AccessorCall, @accessor_invocation_expr {
+  override Accessor getTarget() { expr_call(this, result) }
+
+  override Expr getArgument(int i) { result = this.getChild(i) and i >= 0 }
+
+  override string toString() {
+    result = "call to extension accessor " + concat(this.getTarget().getName())
+  }
+
+  override string getAPrimaryQlClass() { result = "ExtensionAccessorCall" }
+}
+
 /**
  * A call to a property accessor, for example the call to `get_P` on
  * line 5 in
@@ -658,6 +710,29 @@ class IndexerCall extends AccessorCall, IndexerAccessExpr {
   override string getAPrimaryQlClass() { result = "IndexerCall" }
 }
 
+/**
+ * A call to an extension property accessor (via the property), for example
+ * `s.FirstChar` on line 9 in
+ * ```csharp
+ * static class MyExtensions {
+ *   extension(string s) {
+ *     public char FirstChar { get { ... } }
+ *   }
+ * }
+ *
+ * class A {
+ *   char M(string s) {
+ *     return s.FirstChar;
+ *   }
+ * }
+ * ```
+ */
+class ExtensionPropertyCall extends PropertyCall {
+  ExtensionPropertyCall() { this.getProperty() instanceof ExtensionProperty }
+
+  override string getAPrimaryQlClass() { result = "ExtensionPropertyCall" }
+}
+
 /**
  * A call to an event accessor, for example the call to `add_Click`
  * (defined on line 5) on line 12 in