nixvim/wrappers/darwin.nix at main · inclyc/nixvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
{
  modules,
  self,
  getHelpers,
}: {
  pkgs,
  config,
  lib,
  ...
} @ args: let
  inherit (lib) mkEnableOption mkOption mkOptionType mkForce mkMerge mkIf types;
  helpers = getHelpers pkgs false;
  shared = import ./_shared.nix {inherit modules helpers;} args;
  cfg = config.programs.nixvim;
in {
  options = {
    programs.nixvim = mkOption {
      default = {};
      type = types.submoduleWith {
        shorthandOnlyDefinesConfig = true;
        specialArgs = {
          darwinConfig = config;
          inherit helpers;
        };
        modules =
          [
            {
              options.enable = mkEnableOption "nixvim";
              config.wrapRc = mkForce true;
            }
          ]
          ++ shared.topLevelModules;
      };
    };
    nixvim.helpers = shared.helpers;
  };

  config = mkIf cfg.enable (mkMerge [
    {
      environment.systemPackages =
        [
          cfg.finalPackage
          cfg.printInitPackage
        ]
        ++ (lib.optional cfg.enableMan self.packages.${pkgs.system}.man-docs);
    }
    {
      inherit (cfg) warnings assertions;
    }
  ]);
}