Add DLSS support using CUDA API in DLSS 310.5.3

Author: dlacewellNV

.gitignore

@@ -1,3 +1,6 @@
+.cursorrules
+.cursor/
+.claude/
 .editorconfig
 *.ncu-rep
 *~
@@ -8,19 +11,18 @@ assets/**
 benchmark-*/
 build*/
 imgui.ini
-.projectile
 optix.props
 private.cmake
 tmp*.png
 tmp/
 __pycache__/
 vs-chromium-project.txt
-ClusterApi/codegen/input/*/*.ppm
-ClusterApi/codegen/input/*/*.log
 scenes
 scenes/**
 data
 data/**
+reference
+reference/**
 hooks/
 lfs/
 log

.gitmodules

@@ -1,3 +0,0 @@
-[submodule "extern/osd_lite"]
-	path = extern/osd_lite
-	url = https://github.com/NVIDIA-RTX/OSD-Lite

CMake/FetchDLSS.cmake

@@ -0,0 +1,117 @@
+#
+# FetchDLSS.cmake
+#
+# Fetches the NVIDIA DLSS loader package (aka NGX SDK) via FetchContent.
+# This library is used to load the DLSS-RR model at runtime.
+#
+# Creates imported target:
+#   DLSS::DLSS - The DLSS loader library
+#
+# CRT Selection (Windows):
+#   The SDK provides both static (/MT) and dynamic (/MD) CRT versions.
+#   This module automatically uses the version matching your project's CRT setting.
+#
+# Runtime Dependencies:
+#   The DLSS runtime library (DLL/SO) must be beside the executable.
+#   Use dlss_setup_runtime_dependencies(TARGET) after linking to set this up.
+#
+# Local Override:
+#   Set DLSS_ROOT to use a local SDK instead of fetching.
+#
+
+include(FetchContent)
+
+set(DLSS_VERSION "310.5.3" CACHE STRING "DLSS SDK version")
+set(DLSS_URL "https://github.com/NVIDIA/DLSS/archive/refs/tags/v${DLSS_VERSION}.tar.gz" CACHE STRING "URL for DLSS SDK archive")
+set(DLSS_URL_HASH "6b54a684b5b31e819a51742ad534abb4e8cdada76572f061a5d3149c7432a0a1" CACHE STRING "SHA256 hash for DLSS archive")
+
+# Folder name for IDE organization
+set(DLSS_FOLDER_NAME "external/dlss" CACHE STRING "Folder name for grouping DLSS in IDEs")
+
+# If a local source is specified, prefer it (e.g., for offline builds or existing SDK installs)
+if(DEFINED DLSS_ROOT AND EXISTS "${DLSS_ROOT}/include/nvsdk_ngx.h")
+    get_filename_component(DLSS_ROOT "${DLSS_ROOT}" ABSOLUTE)
+    message(STATUS "DLSS: Using local SDK at: ${DLSS_ROOT}")
+    set(_dlss_source_dir "${DLSS_ROOT}")
+else()
+    # Fetch from archive
+    message(STATUS "DLSS: Fetching SDK v${DLSS_VERSION} from GitHub...")
+    if(DLSS_URL_HASH)
+        FetchContent_Declare(dlss URL "${DLSS_URL}" URL_HASH SHA256=${DLSS_URL_HASH})
+    else()
+        FetchContent_Declare(dlss URL "${DLSS_URL}")
+    endif()
+    FetchContent_MakeAvailable(dlss)
+    FetchContent_GetProperties(dlss)
+    set(_dlss_source_dir "${dlss_SOURCE_DIR}")
+    message(STATUS "DLSS: Fetched to: ${_dlss_source_dir}")
+endif()
+
+# Locate components within the SDK
+set(DLSS_INCLUDE_DIR "${_dlss_source_dir}/include")
+
+if(WIN32)
+    # Determine CRT flavor (dynamic /MD vs static /MT)
+    set(_dlss_crt_flavor "d")  # dynamic by default
+    if(CMAKE_MSVC_RUNTIME_LIBRARY MATCHES "MultiThreaded[^D]*$")
+        set(_dlss_crt_flavor "s")
+    endif()
+
+    set(DLSS_LIBRARY_RELEASE "${_dlss_source_dir}/lib/Windows_x86_64/x64/nvsdk_ngx_${_dlss_crt_flavor}.lib")
+    set(DLSS_LIBRARY_DEBUG "${_dlss_source_dir}/lib/Windows_x86_64/x64/nvsdk_ngx_${_dlss_crt_flavor}_dbg.lib")
+    set(DLSS_RUNTIME_LIBRARY_DEVELOP "${_dlss_source_dir}/lib/Windows_x86_64/dev/nvngx_dlssd.dll")
+    set(DLSS_RUNTIME_LIBRARY_RELEASE "${_dlss_source_dir}/lib/Windows_x86_64/rel/nvngx_dlssd.dll")
+else()
+    set(DLSS_LIBRARY_RELEASE "${_dlss_source_dir}/lib/Linux_x86_64/libnvsdk_ngx.a")
+    set(DLSS_LIBRARY_DEBUG "${DLSS_LIBRARY_RELEASE}")
+    file(GLOB _dlss_dev_so "${_dlss_source_dir}/lib/Linux_x86_64/dev/libnvidia-ngx-dlssd.so*")
+    file(GLOB _dlss_rel_so "${_dlss_source_dir}/lib/Linux_x86_64/rel/libnvidia-ngx-dlssd.so*")
+    if(_dlss_dev_so)
+        list(GET _dlss_dev_so 0 DLSS_RUNTIME_LIBRARY_DEVELOP)
+    endif()
+    if(_dlss_rel_so)
+        list(GET _dlss_rel_so 0 DLSS_RUNTIME_LIBRARY_RELEASE)
+    endif()
+endif()
+
+# Validate we found the essentials
+if(EXISTS "${DLSS_INCLUDE_DIR}/nvsdk_ngx.h" AND EXISTS "${DLSS_LIBRARY_RELEASE}")
+    set(DLSS_FOUND TRUE)
+else()
+    set(DLSS_FOUND FALSE)
+    message(WARNING "DLSS: SDK structure not as expected. Include: ${DLSS_INCLUDE_DIR}, Lib: ${DLSS_LIBRARY_RELEASE}")
+    return()
+endif()
+
+# Create imported target
+if(NOT TARGET DLSS::DLSS)
+    add_library(DLSS::DLSS STATIC IMPORTED GLOBAL)
+    set_target_properties(DLSS::DLSS PROPERTIES
+        IMPORTED_CONFIGURATIONS "Debug;Release;RelWithDebInfo"
+        IMPORTED_LINK_INTERFACE_LANGUAGES "CXX;CUDA"
+        INTERFACE_COMPILE_DEFINITIONS "DLSS_ENABLED"
+        INTERFACE_INCLUDE_DIRECTORIES "${DLSS_INCLUDE_DIR}"
+        IMPORTED_LOCATION_RELEASE "${DLSS_LIBRARY_RELEASE}"
+        IMPORTED_LOCATION_RELWITHDEBINFO "${DLSS_LIBRARY_RELEASE}"
+        IMPORTED_LOCATION_DEBUG "${DLSS_LIBRARY_DEBUG}"
+    )
+endif()
+
+message(STATUS "DLSS: Found SDK v${DLSS_VERSION}")
+message(STATUS "DLSS: Release library: ${DLSS_LIBRARY_RELEASE}")
+message(STATUS "DLSS: Debug library: ${DLSS_LIBRARY_DEBUG}")
+
+# Function to copy runtime library beside executable
+function(dlss_setup_runtime_dependencies TARGET)
+    if(NOT DLSS_RUNTIME_LIBRARY_DEVELOP AND NOT DLSS_RUNTIME_LIBRARY_RELEASE)
+        message(WARNING "DLSS: Runtime libraries not found, skipping runtime setup")
+        return()
+    endif()
+
+    add_custom_command(TARGET ${TARGET} POST_BUILD
+        COMMAND ${CMAKE_COMMAND} -E copy_if_different
+            "$<IF:$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>,${DLSS_RUNTIME_LIBRARY_DEVELOP},${DLSS_RUNTIME_LIBRARY_RELEASE}>"
+            "$<TARGET_FILE_DIR:${TARGET}>/$<IF:$<PLATFORM_ID:Windows>,nvngx_dlssd.dll,libnvidia-ngx-dlssd.so>"
+        COMMENT "DLSS: Copying runtime library"
+    )
+endfunction()

CMake/FetchOsdLite.cmake

@@ -0,0 +1,47 @@
+#
+# Helper to bring in OSD-Lite via CMake FetchContent, with local override
+#
+
+include(FetchContent)
+
+set(OSD_LITE_GIT_REPOSITORY "https://github.com/NVIDIA-RTX/OSD-Lite.git" CACHE STRING "Git repository for osd_lite")
+set(OSD_LITE_GIT_TAG "c0c3404b62ee4b39c1a7c77d72a13ee9712f37ca" CACHE STRING "Git tag/branch/commit for osd_lite")
+
+# Folder name for IDE organization of osd_lite targets
+set(OSD_LITE_FOLDER_NAME "external/osd_lite" CACHE STRING "Folder name for grouping osd_lite targets in IDEs")
+
+# If a local source is specified, prefer it (e.g., for offline builds)
+if(DEFINED OSD_LITE_SOURCE_DIR AND EXISTS "${OSD_LITE_SOURCE_DIR}/CMakeLists.txt")
+  # Normalize to absolute path
+  get_filename_component(OSD_LITE_SOURCE_DIR "${OSD_LITE_SOURCE_DIR}" ABSOLUTE)
+  message(STATUS "Using local OSD-Lite at: ${OSD_LITE_SOURCE_DIR}")
+  add_subdirectory("${OSD_LITE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}/_deps/osd_lite-build" EXCLUDE_FROM_ALL)
+  # Ensure OSD-Lite headers are treated as system to avoid third-party warnings
+  include_directories(SYSTEM
+    ${OSD_LITE_SOURCE_DIR}
+    ${OSD_LITE_SOURCE_DIR}/opensubdiv
+    ${OSD_LITE_SOURCE_DIR}/opensubdiv/tmr)
+else()
+  # Fetch from git
+  message(STATUS "Fetching OSD-Lite from: ${OSD_LITE_GIT_REPOSITORY} @ ${OSD_LITE_GIT_TAG}")
+  FetchContent_Declare(
+    osd_lite
+    GIT_REPOSITORY "${OSD_LITE_GIT_REPOSITORY}"
+    GIT_TAG        "${OSD_LITE_GIT_TAG}"
+    GIT_PROGRESS   TRUE
+  )
+  FetchContent_MakeAvailable(osd_lite)
+
+  # Resolve source dir for include path adjustments
+  FetchContent_GetProperties(osd_lite)
+  if(osd_lite_SOURCE_DIR)
+    message(STATUS "Using fetched OSD-Lite at: ${osd_lite_SOURCE_DIR}")
+    # Ensure OSD-Lite headers are treated as system to avoid third-party warnings
+    include_directories(SYSTEM
+      ${osd_lite_SOURCE_DIR}
+      ${osd_lite_SOURCE_DIR}/opensubdiv
+      ${osd_lite_SOURCE_DIR}/opensubdiv/tmr)
+  endif()
+endif()
+
+

CMake/embed_cuda.cmake

@@ -104,7 +104,11 @@ function(embed_cuda)
   if(EMBED_CUDA_PTX)
     set_property(TARGET ${CUDA_TARGET} PROPERTY CUDA_PTX_COMPILATION ON)
   else()
-    set_property(TARGET ${CUDA_TARGET} PROPERTY CUDA_OPTIX_COMPILATION ON)
+    if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.27.7")
+      set_property(TARGET ${CUDA_TARGET} PROPERTY CUDA_OPTIX_COMPILATION ON)
+    else()
+      target_compile_options(${CUDA_TARGET} PRIVATE "-optix-ir")
+    endif()
   endif()
 
 

CMake/run_bin2c.cmake

@@ -54,7 +54,7 @@ foreach(obj ${OBJECTS})
   if(NOT EXISTS ${obj})
     message(FATAL_ERORR "${obj} does not exist.")
     set(file_contents "${file_contents}\n#error ${obj} does not exist.\n")
-  elseif(obj_ext MATCHES ".ptx" OR obj_ext MATCHES ".optixir")
+  elseif(obj_ext MATCHES ".ptx" OR obj_ext MATCHES ".optixir" OR obj_ext MATCHES ".o")
     set(args --name ${obj_name} ${obj})
     if(obj_ext MATCHES ".ptx")
       list(APPEND(args --padd 0,0))

CMakeLists.txt

@@ -32,8 +32,13 @@
 # Include developer's "private.cmake" (if any) for ad hoc customization.
 include( "private.cmake" OPTIONAL )
 
-# Minimum version of cmake to support OptiXIR compilation
-cmake_minimum_required(VERSION 3.27.7 FATAL_ERROR)
+
+if(WIN32)
+    # newer cmake has better optixir support with MSVC
+    cmake_minimum_required(VERSION 3.27.7 FATAL_ERROR)
+else()
+    cmake_minimum_required(VERSION 3.25.3 FATAL_ERROR)
+endif()
 
 # Temporarily quiet some warnings related to FetchContent usage
 if(POLICY CMP0169)
@@ -56,10 +61,20 @@ endif()
 # default CUDA arch.  This needs to be declared before any project(... CUDA) lines
 set(CMAKE_CUDA_ARCHITECTURES "86" CACHE STRING "")
 
+
 project(OptixSubd LANGUAGES C CXX CUDA VERSION 1.13.0)
 
+find_package(CUDAToolkit 12.0 REQUIRED)
+
 message(STATUS "CMAKE_CUDA_ARCHITECTURES: ${CMAKE_CUDA_ARCHITECTURES}")
 
+# Dynamically link against the CUDA runtime
+if(CUDAToolkit_VERSION VERSION_GREATER_EQUAL "13.0")
+  set(CMAKE_CUDA_RUNTIME_LIBRARY "Hybrid")
+else()
+  set(CMAKE_CUDA_RUNTIME_LIBRARY "Shared")
+endif()
+
 # C++ standards
 
 set(CMAKE_CXX_STANDARD 20)
@@ -93,9 +108,6 @@ if(MSVC)
 else()
     # Ignore warnings from some third party headers by including them with -isystem
     include_directories(SYSTEM
-      ${CMAKE_CURRENT_LIST_DIR}/extern/osd_lite
-      ${CMAKE_CURRENT_LIST_DIR}/extern/osd_lite/opensubdiv
-      ${CMAKE_CURRENT_LIST_DIR}/extern/osd_lite/opensubdiv/tmr
       ${CMAKE_CURRENT_LIST_DIR}/texture
       ${CMAKE_BINARY_DIR}/_deps/implot-src
       ${CMAKE_BINARY_DIR}/_deps/imgui-src
@@ -129,7 +141,6 @@ add_compile_options($<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:CUDA>>:-lineinfo>
 add_compile_options($<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:CUDA>>:-lineinfo>)
 
 
-find_package( CUDAToolkit 12.0 REQUIRED )
 
 
 # TBB (optional) needed for C++17 parallel algorithms on gcc
@@ -157,11 +168,19 @@ add_library(glad::glad ALIAS glad)
 
 add_subdirectory(${CMAKE_CURRENT_LIST_DIR}/optix-toolkit EXCLUDE_FROM_ALL)
 
+# Make OptiX Toolkit use dynamic CUDA runtime
+set(OTK_LINK_CUDA_STATIC OFF CACHE BOOL "Enable static linking against the cuda run-time" FORCE)
 
 # OSD
 add_definitions(-D_USE_MATH_DEFINES)
-set(OSD_LITE_FOLDER_NAME "external/osd_lite")
-add_subdirectory(${CMAKE_CURRENT_LIST_DIR}/extern/osd_lite EXCLUDE_FROM_ALL)
+include(CMake/FetchOsdLite.cmake)
+
+# optional DLSS
+
+option(ENABLE_DLSS "Enable DLSS support if found" ON)
+if(ENABLE_DLSS)
+    include(CMake/FetchDLSS.cmake)
+endif()
 
 
 # Build configuration
@@ -207,6 +226,7 @@ if (MSVC)
 endif()
 
 add_subdirectory(cluster_builder)
+add_subdirectory(depth)
 add_subdirectory(material)
 add_subdirectory(motionvec)
 add_subdirectory(profiler)
@@ -219,8 +239,8 @@ set( optixSubd_SOURCES )
 list( APPEND optixSubd_SOURCES
     args.cpp
     args.h
-    denoiserstub.h
-    denoiserstub.cu
+    denoiser.h
+    denoiserAccum.cu
     GBuffer.cu
     GBuffer.h
     GBuffer.cuh
@@ -241,10 +261,14 @@ list( APPEND optixSubd_SOURCES
     version.cpp
 )
 
+if(DLSS_FOUND AND ENABLE_DLSS)
+    list(APPEND optixSubd_SOURCES denoiserDlss.cu)
+endif()
 
 add_executable( optixSubd
     ${optixSubd_SOURCES}
     $<TARGET_OBJECTS:cluster_builder>
+    $<TARGET_OBJECTS:depth>
     $<TARGET_OBJECTS:material>
     $<TARGET_OBJECTS:motionvec>
     $<TARGET_OBJECTS:profiler>
@@ -256,11 +280,13 @@ add_executable( optixSubd
 target_include_directories( optixSubd PRIVATE
     ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/EmbeddedDeviceCode
     ${CMAKE_CURRENT_SOURCE_DIR}
+    ${CUDAToolkit_INCLUDE_DIRS}  # Add CUDA include paths to help find system headers
 )
 
 target_link_libraries( optixSubd
   PRIVATE
     EmbeddedDeviceCode
+    DepthPassDeviceCode
     OptiXToolkit::Gui
     OptiXToolkit::Util
     OptiXToolkit::ShaderUtil
@@ -274,6 +300,11 @@ target_link_libraries( optixSubd
     ${CMAKE_DL_LIBS}  
 )
 
+if(DLSS_FOUND AND ENABLE_DLSS)
+    target_compile_definitions(optixSubd PRIVATE DLSS_ENABLED)
+    target_link_libraries(optixSubd PRIVATE DLSS::DLSS)
+    dlss_setup_runtime_dependencies(optixSubd)
+endif()
 
 # Optionally link tbb for parallel C++17 algorithms on gcc
 if ( TBB_FOUND )
@@ -301,6 +332,7 @@ endif()
 # dependencies are not compatible with more strict warnings.
 foreach(TARGET
   #cluster_builder
+  depth
   material
   motionvec
   profiler

GBuffer.cu

@@ -190,6 +190,9 @@ GBuffer::GBuffer( uint2 rendersize, uint2 targetsize )
     ::create( m_motionvecs, rendersize );
     ::create( m_color, rendersize );
     ::create( m_depth, rendersize );
+    ::create( m_specular, rendersize );
+    ::create( m_roughness, rendersize );
+    ::create( m_specularHitT, rendersize );
 
     ::create( m_depthHires, targetsize );
     ::create( m_denoised, targetsize );
@@ -284,9 +287,11 @@ void GBuffer::blit( Channel channel, uchar4* output, uint2 outputSize, CUstream
         case Channel::MOTIONVECS:    launchKernel( m_motionvecs ); break;
         case Channel::DEPTH:         launchKernel( m_depth ); break;
         case Channel::DEPTH_HIRES:   launchKernel( m_depthHires ); break;
-
         case Channel::DENOISED:      launchKernel( m_denoised, sRGB_Operator{} ); break;
         case Channel::COLOR:         launchKernel( m_color, sRGB_Operator{} ); break;
+        case Channel::SPECULAR:      launchKernel( m_specular ); break;
+        case Channel::ROUGHNESS:     launchKernel( m_roughness ); break;
+        case Channel::SPECULAR_HIT_T: launchKernel( m_specularHitT ); break;
     }
 }