r7z/flake.nix at main · mjc/r7z · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
{
  description = "r7z - Pure-Rust 7z archive library";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    rust-overlay,
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      overlays = [(import rust-overlay)];
      pkgs = import nixpkgs {
        inherit system overlays;
      };

      rustToolchain = pkgs.rust-bin.stable.latest.default.override {
        extensions = ["rust-src" "rust-analyzer" "llvm-tools-preview"];
      };

      nativeBuildInputs = with pkgs;
        [
          rustToolchain
          cargo-flamegraph
          cargo-nextest
          gnuplot
          hyperfine
        ]
        ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
          perf
          valgrind
        ];

      cargoTargetEnvPrefix =
        pkgs.lib.toUpper (builtins.replaceStrings ["-"] ["_"]
          pkgs.stdenv.hostPlatform.rust.rustcTargetSpec);
    in {
      devShells.default = pkgs.mkShell {
        inherit nativeBuildInputs;

        shellHook = ''
          export RUST_SRC_PATH="${rustToolchain}/lib/rustlib/src/rust/library"
          export CARGO_TARGET_${cargoTargetEnvPrefix}_RUSTFLAGS="-C target-cpu=native"
          echo "r7z dev shell  ($(rustc --version))"
        '';
      };
    });
}