{grafana,yarn-berry_{3,4}-fetcher}: Fix cross (NixOS#465092)

Author: Artturin

pkgs/by-name/ya/yarn-berry/fetcher/default.nix

@@ -1,12 +1,13 @@
 {
   lib,
-  newScope,
   yarn-berry,
   yarn,
   replaceVars,
   libzip,
   zlib,
   zlib-ng,
+  makeScopeWithSplicing',
+  generateSplicesForMkScope,
 }:
 
 let
@@ -56,32 +57,36 @@ let
           });
     };
   };
-in
 
-lib.makeScope newScope (
-  final:
-  let
-    berryVersion = lib.versions.major yarn-berry.version;
+  berryVersion = lib.versions.major yarn-berry.version;
+
+  otherSplices = generateSplicesForMkScope "yarn-berry_${berryVersion}-fetcher";
+in
 
-    err = throw ''
-      Berry version ${toString berryVersion} not supported by yarn-berry-fetcher.
-      Supported versions: ${lib.concatStringsSep ", " (lib.attrNames variantOverlays)}
-    '';
-    variantOverlay = (variantOverlays.${berryVersion} or err) final;
-  in
-  (
-    {
-      inherit yarn-berry berryVersion;
+makeScopeWithSplicing' {
+  inherit otherSplices;
+  f =
+    final:
+    let
+      err = throw ''
+        Berry version ${toString berryVersion} not supported by yarn-berry-fetcher.
+        Supported versions: ${lib.concatStringsSep ", " (lib.attrNames variantOverlays)}
+      '';
+      variantOverlay = (variantOverlays.${berryVersion} or err) final;
+    in
+    (
+      {
+        inherit yarn-berry berryVersion;
 
-      yarn-berry-offline = final.yarn-berry.overrideAttrs (old: {
-        pname = old.pname + "-offline";
-        patches = (old.patches or [ ]) ++ final.berryOfflinePatches;
-      });
+        yarn-berry-offline = final.yarn-berry.overrideAttrs (old: {
+          pname = old.pname + "-offline";
+          patches = (old.patches or [ ]) ++ final.berryOfflinePatches;
+        });
 
-      yarn-berry-fetcher = final.callPackage ./yarn-berry-fetcher.nix { };
-      fetchYarnBerryDeps = final.callPackage ./fetch-yarn-berry-deps.nix { };
-      yarnBerryConfigHook = final.callPackage ./yarn-berry-config-hook.nix { };
-    }
-    // variantOverlay
-  )
-)
+        yarn-berry-fetcher = final.callPackage ./yarn-berry-fetcher.nix { };
+        fetchYarnBerryDeps = final.callPackage ./fetch-yarn-berry-deps.nix { };
+        yarnBerryConfigHook = final.callPackage ./yarn-berry-config-hook.nix { };
+      }
+      // variantOverlay
+    );
+}

pkgs/servers/monitoring/grafana/default.nix

@@ -7,6 +7,8 @@
   tzdata,
   wire,
   yarn-berry_4,
+  yarn-berry_4-fetcher,
+  buildPackages,
   python3,
   jq,
   moreutils,
@@ -44,7 +46,8 @@ buildGoModule (finalAttrs: {
   };
 
   missingHashes = ./missing-hashes.json;
-  offlineCache = yarn-berry_4.fetchYarnBerryDeps {
+  # Since this is not a dependency attribute the buildPackages has to be specified.
+  offlineCache = buildPackages.yarn-berry_4-fetcher.fetchYarnBerryDeps {
     inherit (finalAttrs) src missingHashes;
     hash = "sha256-CAEhdKsFMUuIs8DsJ9xSr2FRdBp4fPUWyvjC6FuiyG8=";
   };
@@ -69,17 +72,19 @@ buildGoModule (finalAttrs: {
 
   proxyVendor = true;
 
+  depsBuildBuild = [ buildPackages.stdenv.cc ];
+
   nativeBuildInputs = [
     wire
     jq
     moreutils
     removeReferencesTo
     # required to run old node-gyp
-    (python3.withPackages (ps: [ ps.distutils ]))
+    (python3.pythonOnBuildForHost.withPackages (ps: [ ps.distutils ]))
     faketty
     nodejs
     yarn-berry_4
-    yarn-berry_4.yarnBerryConfigHook
+    yarn-berry_4-fetcher.yarnBerryConfigHook
   ]
   ++ lib.optionals stdenv.hostPlatform.isDarwin [ xcbuild.xcbuild ];
 
@@ -88,7 +93,7 @@ buildGoModule (finalAttrs: {
   overrideModAttrs = (
     old: {
       nativeBuildInputs = lib.filter (
-        x: lib.getName x != (lib.getName yarn-berry_4.yarnBerryConfigHook)
+        x: lib.getName x != (lib.getName buildPackages.yarn-berry_4-fetcher.yarnBerryConfigHook)
       ) old.nativeBuildInputs;
     }
   );
@@ -99,9 +104,14 @@ buildGoModule (finalAttrs: {
     wire gen -tags oss ./pkg/server
     wire gen -tags oss ./pkg/cmd/grafana-cli/runner
 
-    GOARCH= CGO_ENABLED=0 go generate ./kinds/gen.go
-    GOARCH= CGO_ENABLED=0 go generate ./public/app/plugins/gen.go
-
+    # ```
+    # go-1.25.4/share/go/pkg/tool/linux_amd64/link: running aarch64-unknown-linux-gnu-gcc failed: exit status 1
+    # aarch64-unknown-linux-gnu-gcc -m64 -s -o $WORK/b001/exe/gen -rdynamic /build/go-link-507658645/go.o
+    # aarch64-unknown-linux-gnu-gcc: error: unrecognized command-line option '-m64'
+    # ```
+    # Above log is due to https://github.com/golang/go/blob/b194f5d24a71e34f147c90e4351d80ac75be55de/src/cmd/cgo/gcc.go#L1763
+    CC="$CC_FOR_BUILD" LD="$CC_FOR_BUILD" GOOS= GOARCH= CGO_ENABLED=0 go generate ./kinds/gen.go
+    CC="$CC_FOR_BUILD" LD="$LD_FOR_BUILD" GOOS= GOARCH= CGO_ENABLED=0 go generate ./public/app/plugins/gen.go
   '';
 
   postBuild = ''

pkgs/top-level/all-packages.nix

@@ -4184,7 +4184,13 @@ with pkgs;
   yapf = with python3Packages; toPythonApplication yapf;
 
   yarn-berry_4 = yarn-berry.override { berryVersion = 4; };
+  yarn-berry_4-fetcher = callPackage ../by-name/ya/yarn-berry/fetcher {
+    yarn-berry = yarn-berry_4;
+  };
   yarn-berry_3 = yarn-berry.override { berryVersion = 3; };
+  yarn-berry_3-fetcher = callPackage ../by-name/ya/yarn-berry/fetcher {
+    yarn-berry = yarn-berry_3;
+  };
 
   yarn2nix-moretea = callPackage ../development/tools/yarn2nix-moretea { };