build: add nix build scripts (#14)

* feat: nixify

* chore: update docs

Author: willruggiano

.gitignore

@@ -1,5 +1,32 @@
-/target
+# Created by https://www.toptal.com/developers/gitignore/api/rust,direnv
+# Edit at https://www.toptal.com/developers/gitignore?templates=rust,direnv
 
+### Direnv ###
+.direnv
+.envrc
 .env
+
+### Pre-commit ###
+.pre-commit-config.yaml
+
+### Rust ###
+# Generated by Cargo
+# will have compiled files and executables
+debug/
+target/
+
+# Remove Cargo.lock from gitignore if creating an executable, leave it for libraries
+# More information here https://doc.rust-lang.org/cargo/guide/cargo-toml-vs-cargo-lock.html
+Cargo.lock
+
+# These are backup files generated by rustfmt
+**/*.rs.bk
+
+# MSVC Windows builds of rustc generate these, which store debugging information
+*.pdb
+
+### Misc ###
 data.db
 data.db*
+
+# End of https://www.toptal.com/developers/gitignore/api/rust,direnv

.rust-toolchain

@@ -1,2 +1,4 @@
 [toolchain]
 channel = "1.66"
+components = [ "clippy", "llvm-tools-preview", "rust-analyzer", "rust-src" ]
+profile = "default"

README.md

@@ -58,6 +58,23 @@ return {
   },
 }
 ```
+
+### Nix(OS)
+
+The project is packaged as a [Nix Flake][nix-flakes]. Consume it as you normally would. In your Nix configuration,
+*make sure* that sg-nvim is included *both* as a Neovim plugin *and* as an environment/user package
+(because `sg-lsp` needs to be on your PATH).
+
+See https://nixos.wiki/wiki/Neovim for more details on configuring neovim using Nix.
+Or see https://github.com/willruggiano/neovim.drv for a practical example.
+
+For contributors and maintainers:
+
+- There should be nothing to do, nix-related, when changes are made to the Rust project
+- If you're Nix savvy and want to contribute, it would be nice to use [crate2nix] instead
+  of the generic `buildRustPackage`. A github workflow would be needed to autoupdate the
+  generated crate2nix files.
+
 ### Setup:
 
 ```lua
@@ -83,3 +100,5 @@ nnoremap <space>ss <cmd>lua require('sg.telescope').fuzzy_search_results()<CR>
 - Demo v2: [YouTube](https://www.youtube.com/watch?v=RCyBnAx-4Q4)
 - Demo v1: [YouTube](https://youtu.be/iCdsD6MiLQs)
 
+[nix-flakes]: https://nixos.wiki/wiki/Flakes
+[crate2nix]: https://github.com/kolloch/crate2nix

default.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  rustPlatform,
+  toolchain,
+  pkg-config,
+  openssl,
+  ...
+}:
+rustPlatform.buildRustPackage {
+  pname = "sg.nvim";
+  version = "0.1.0";
+
+  src = ./.;
+  cargoLock = {
+    lockFile = ./Cargo.lock;
+  };
+
+  nativeBuildInputs = [pkg-config toolchain];
+  buildInputs = [openssl];
+
+  cargoBuildFlags = ["--workspace"];
+  cargoTestFlags = ["--workspace"];
+
+  checkFlags = [
+    "--skip=test::can_get_lines_and_columns"
+    "--skip=test::create"
+  ];
+
+  postInstall = ''
+    cp -R {lua,plugin} $out
+  '';
+
+  meta = with lib; {
+    description = "";
+    homepage = "https://github.com/tjdevries/sg.nvim";
+    license = licenses.unlicense;
+  };
+}

flake.lock

@@ -0,0 +1,65 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    pre-commit-nix.url = "github:cachix/pre-commit-hooks.nix";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+  };
+
+  outputs = {
+    self,
+    flake-parts,
+    ...
+  } @ inputs:
+    flake-parts.lib.mkFlake {inherit inputs;} {
+      imports = [
+        inputs.pre-commit-nix.flakeModule
+      ];
+
+      flake = {
+        overlays.default = final: prev: {
+          sg-nvim = self.packages."${prev.system}".default;
+        };
+      };
+
+      systems = ["x86_64-linux" "aarch64-darwin"];
+      perSystem = {
+        config,
+        system,
+        inputs',
+        ...
+      }: let
+        pkgs = import inputs.nixpkgs {
+          inherit system;
+          overlays = [
+            inputs.rust-overlay.overlays.default
+          ];
+        };
+        toolchain = pkgs.rust-bin.fromRustupToolchainFile ./.rust-toolchain;
+      in {
+        devShells.default = pkgs.mkShell {
+          name = "sg.nvim";
+          buildInputs = with pkgs; [
+            openssl
+            pkg-config
+            toolchain
+          ];
+          shellHook = ''
+            ${config.pre-commit.installationScript}
+          '';
+        };
+
+        formatter = pkgs.alejandra;
+
+        packages.default = pkgs.callPackage ./. {inherit toolchain;};
+
+        pre-commit = {
+          settings = {
+            hooks.alejandra.enable = true;
+            hooks.rustfmt.enable = true;
+            hooks.cargo-check.enable = true;
+          };
+        };
+      };
+    };
+}