diff --git a/README.md b/README.md
index 91e20bb19..2dcfdd69c 100644
--- a/README.md
+++ b/README.md
@@ -15,6 +15,16 @@ If you really want to build it yourself, the simplest way to do so is to run the
 
 * Open a dev command prompt pointing at the root of the repo.
 * Open the `cppwinrt.sln` solution.
-* Build the x64 Release configuration of the `prebuild` and `cppwinrt` projects only. Do not attempt to build anything else just yet.
+* Build the x64 Release configuration of the `cppwinrt` project only. Do not attempt to build anything else just yet.
 * Run `build_projection.cmd` in the dev command prompt.
 * Switch to the x64 Debug configuration in Visual Studio and build all projects as needed.
+
+## Comparing Outputs
+
+Comparing the output of the prior release and your current changes will help show the impact of any updates. Starting from
+a dev command prompt at the root of the repo _after_ following the above build instructions:
+
+* Run `build_projection.cmd` in the dev command prompt
+* Run `build_prior_projection.cmd` in the dev command prompt as well
+* Run `prepare_versionless_diffs.cmd` which removes version stamps on both current and prior projection
+* Use a directory-level differencing tool to compare `_build\$(arch)\$(flavor)\winrt` and `_reference\$(arch)\$(flavor)\winrt`
diff --git a/build_prior_projection.cmd b/build_prior_projection.cmd
new file mode 100644
index 000000000..c7bdf2f64
--- /dev/null
+++ b/build_prior_projection.cmd
@@ -0,0 +1,50 @@
+@echo off
+
+setlocal ENABLEDELAYEDEXPANSION
+
+set target_platform=%1
+set target_configuration=%2
+if "%target_platform%"=="" set target_platform=x64
+
+if /I "%target_platform%" equ "all" (
+  if "%target_configuration%"=="" (
+    set target_configuration=all
+  )
+  call %0 x86 !target_configuration!
+  call %0 x64 !target_configuration!
+  call %0 arm !target_configuration!
+  call %0 arm64 !target_configuration!
+  goto :eof
+)
+
+if /I "%target_configuration%" equ "all" (
+  call %0 %target_platform% Debug
+  call %0 %target_platform% Release
+  goto :eof
+)
+
+if "%target_configuration%"=="" (
+ set target_configuration=Debug
+)
+
+set reference_output=%~p0\_reference\%target_platform%\%target_configuration%
+if exist "%reference_output%" (
+ echo Removing existing reference projections
+ rmdir /s /q "%reference_output%"
+)
+
+if not exist ".\.nuget" mkdir ".\.nuget"
+if not exist ".\.nuget\nuget.exe" powershell -Command "$ProgressPreference = 'SilentlyContinue' ; Invoke-WebRequest https://dist.nuget.org/win-x86-commandline/latest/nuget.exe -OutFile .\.nuget\nuget.exe"
+
+mkdir %reference_output%\package
+.\.nuget\nuget.exe install Microsoft.Windows.CppWinRT -o %reference_output%\package
+set reference_cppwinrt=
+for /F "delims=" %%a in ('dir /s /b %reference_output%\package\cppwinrt.exe') DO set reference_cppwinrt=%%a
+if "%reference_cppwinrt%"=="" (
+ echo Could not find the reference cppwinrt.exe under %reference_output%\package
+ goto :EOF
+)
+
+echo Generating reference projection from %reference_cppwinrt% to %reference_output%\cppwinrt
+%reference_cppwinrt% -in local -out %reference_output% -verbose
+echo.
diff --git a/build_projection.cmd b/build_projection.cmd
index 9480b5ec0..778fa7aca 100644
--- a/build_projection.cmd
+++ b/build_projection.cmd
@@ -27,6 +27,13 @@ if "%target_configuration%"=="" (
  set target_configuration=Debug
 )
 
+set cppwinrt_exe=%~p0\_build\x64\Release\cppwinrt.exe
+
+if not exist "%cppwinrt_exe%" (
+ echo Remember to build the "prebuild" and then "cppwinrt" projects for Release x64 first
+ goto :eof
+)
+
 echo Building projection into %target_platform% %target_configuration%
-%~p0\_build\x64\Release\cppwinrt.exe -in local -out %~p0\_build\%target_platform%\%target_configuration% -verbose
+%cppwinrt_exe% -in local -out %~p0\_build\%target_platform%\%target_configuration% -verbose
 echo.
diff --git a/build_test_all.cmd b/build_test_all.cmd
index 6f7e24033..681f8c682 100644
--- a/build_test_all.cmd
+++ b/build_test_all.cmd
@@ -10,7 +10,7 @@ if "%target_configuration%"=="" set target_configuration=Release
 if "%target_version%"=="" set target_version=1.2.3.4
 
 if not exist ".\.nuget" mkdir ".\.nuget"
-if not exist ".\.nuget\nuget.exe" powershell -Command "Invoke-WebRequest https://dist.nuget.org/win-x86-commandline/latest/nuget.exe -OutFile .\.nuget\nuget.exe"
+if not exist ".\.nuget\nuget.exe" powershell -Command "$ProgressPreference = 'SilentlyContinue' ; Invoke-WebRequest https://dist.nuget.org/win-x86-commandline/latest/nuget.exe -OutFile .\.nuget\nuget.exe"
 
 call .nuget\nuget.exe restore cppwinrt.sln"
 call .nuget\nuget.exe restore natvis\cppwinrtvisualizer.sln
diff --git a/prepare_versionless_diffs.cmd b/prepare_versionless_diffs.cmd
new file mode 100644
index 000000000..468645657
--- /dev/null
+++ b/prepare_versionless_diffs.cmd
@@ -0,0 +1,41 @@
+@echo off
+
+setlocal ENABLEDELAYEDEXPANSION
+
+set target_platform=%1
+set target_configuration=%2
+if "%target_platform%"=="" set target_platform=x64
+
+if /I "%target_platform%" equ "all" (
+  if "%target_configuration%"=="" (
+    set target_configuration=all
+  )
+  call %0 x86 !target_configuration!
+  call %0 x64 !target_configuration!
+  call %0 arm !target_configuration!
+  call %0 arm64 !target_configuration!
+  goto :eof
+)
+
+if /I "%target_configuration%" equ "all" (
+  call %0 %target_platform% Debug
+  call %0 %target_platform% Release
+  goto :eof
+)
+
+if "%target_configuration%"=="" (
+ set target_configuration=Debug
+)
+
+set reference_output=%~p0\_reference\%target_platform%\%target_configuration%
+set build_output=%~p0\_build\%target_platform%\%target_configuration%
+
+echo Removing version stamps from %reference_output%\winrt
+pushd %reference_output%\winrt
+powershell -Command "gci -r -include *.h,*.ixx | %%{ (get-content $_) -replace 'was generated by.*|CPPWINRT_VERSION.*','' | set-content $_ }"
+popd
+
+echo Removing version stamps from %build_output%\winrt
+pushd %build_output%\winrt
+powershell -Command "gci -r -include *.h,*.ixx | %%{ (get-content $_) -replace 'was generated by.*|CPPWINRT_VERSION.*','' | set-content $_ }"
+popd