3d-door-latch-spacer/door_latch_spacer.scad at master · vsergeev/3d-door-latch-spacer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
/********************************************************
 * Door Latch Spacer - vsergeev
 * https://github.com/vsergeev/3d-door-latch-spacer
 * CC-BY-4.0
 *
 * Release Notes
 *  * v1.0 - 06/20/2023
 *      * Initial release.
 ********************************************************/

/* [Basic] */

// in mm
spacer_z_thickness = 2;

/* [Advanced] */

// in mm (1 * 25.4)
spacer_x_width = 25.4;

// in mm (2.25 * 25.4)
spacer_y_height = 57.15;

// in mm
spacer_xy_radius = 6.5;

// in mm (1.6 * 25.4)
spacer_screw_y_spacing = 40.64;

// in mm (0.25 * 25.4)
spacer_screw_xy_diameter = 6.35;

// in mm (1.075 * 0.8 * 25.4)
spacer_latch_xy_diameter = 21.844;

/* [Hidden] */

$fn = 100;

/******************************************************************************/
/* 2D Profiles */
/******************************************************************************/

module profile_spacer() {
    difference() {
        /* Spacer Body */
        offset(r=spacer_xy_radius)
            offset(delta=-spacer_xy_radius)
                square([spacer_x_width, spacer_y_height], center=true);

        /* Screw Holes */
        translate([0, spacer_screw_y_spacing / 2])
            circle(d=spacer_screw_xy_diameter);
        translate([0, -spacer_screw_y_spacing / 2])
            circle(d=spacer_screw_xy_diameter);

        /* Latch Opening */
        circle(d=spacer_latch_xy_diameter);
    }
}

/******************************************************************************/
/* 3D Extrusions */
/******************************************************************************/

module spacer() {
    linear_extrude(spacer_z_thickness)
        profile_spacer();
}

/******************************************************************************/
/* Top Level */
/******************************************************************************/

spacer();