Transient for symbol-overlay

[hmelman]

For what it's worth, I've been very happily using this transient for symbol-overlay for a while. It could be bound to any key but I have a super- key configured and am binding this to s-. which I find nicely parallels M-..

(define-transient-command symbol-overlay-transient ()
  "Symbol Overlay transient"
  ["Symbol Overlay"
   ["Overlays"
    ("." "Add/Remove at point" symbol-overlay-put)
    ("k" "Remove All" symbol-overlay-remove-all)
    ]
   ["Move to Symbol"
    ("n" "Next" symbol-overlay-switch-forward)
    ("p" "Previous" symbol-overlay-switch-backward)
    ]
   ["Other"
    ("m" "Highlight symbol-at-point" symbol-overlay-mode)
    ]
   ]
  )
(global-set-key (kbd "s-.") 'symbol-overlay-transient)

[purcell]

Great - thanks for sharing! It's out of scope to add a depenency on transient to the library itself, but I'm sure others will stumble across this and find it helpful! I might link to this snippet from the README...

[Cons-Cat]

With Transient now added in the master branch of Emacs 28, is it possible this might be revisited in the future?

[dandrake]

define-transient-command doesn't seem to exist now in emacs 29; I'm using the following. I also added everything from the h / symbol-overlay-map-help screen. In fact, I think that should be removed in favor of using transient, which is more usable and seems to be the modern idiom (see the "casual suite" for dired, ibuffer, calc, and others):

(transient-define-prefix symbol-overlay-transient ()
  "Symbol Overlay transient"
  ["Symbol Overlay"
   ["Overlays"
    ("." "Add/Remove at point" symbol-overlay-put)
    ("k" "Remove All" symbol-overlay-remove-all)
    ]
   ["Navigation"
    ("<" "Jump to first" symbol-overlay-jump-first)
    (">" "Jump to last" symbol-overlay-jump-last)
    ("n" "Next" symbol-overlay-switch-forward)
    ("p" "Previous" symbol-overlay-switch-backward)
    ("d" "Jump to definition" symbol-overlay-jump-to-definition)
    ("s" "Isearch" symbol-overlay-isearch-literally)
    ]
   ["Operations"
    ("e" "Echo mark" symbol-overlay-echo-mark)
    ("q" "Query replace" symbol-overlay-query-replace)
    ("r" "Rename" symbol-overlay-rename)
    ("w" "Copy to kill ring" symbol-overlay-save-symbol)
    ("t" "Toggle in scope" symbol-overlay-toggle-in-scope)
    ]
   ["Other"
    ("m" "Highlight symbol-at-point" symbol-overlay-mode)
    ]
   ]
  )

[hmelman]

Yeah -command became -prefix. I'm still using the transient I had. I find the commands on the symbol-overlay-map overlay are way more convenient wouldn't want to lose them. I just use the transient to add/remove overlays and to navigate to an overlay when I'm not on one. Otherwise the overlay map is faster, you don't have to type the transient prefix for first/last/rename/etc.

[hmelman]

FWIW, I'm using this transient now. I found I wasn't remembering some of my infrequently used overlay-keymap bindings so I now include them in the transient, clearly marked as being on the overlay-keymap, as a quick reference and a way to hopefully learn them over time.

;; A transient makes symbol-overlay easy to use
;; Include the overlay keymap bindings for quick reference
;; symbol-overlay-remove-all behaves differently when
;; called interactively which calling from the transient
;; doesn't do, so write a command that explicitly
;; calls it interactively

(defun hrm-symbol-overlay-remove-all ()
  "Remove all highlighted symbols in the buffer, always reset
`symbol-overlay-keywords-alist'."
  (interactive)
  (call-interactively 'symbol-overlay-remove-all))

(eval-when-compile (require 'symbol-overlay))
(transient-define-prefix hrm-symbol-overlay-transient ()
  "Symbol Overlay transient"
  ["Symbol Overlay"
   ["Manage"
    ("." "Toggle" symbol-overlay-put)
    ("k" "Remove All" hrm-symbol-overlay-remove-all) ; for called-interactively-p check
    ("m" "Auto Highlight" symbol-overlay-mode) ; a minor mode to highlight symbol-at-point
    ]
   ["Move"
    ("n" "Next" symbol-overlay-switch-forward)
    ("p" "Previous" symbol-overlay-switch-backward)
    ]
   ["On Overlay"
    ("<" "First" symbol-overlay-jump-first)
    (">" "Last" symbol-overlay-jump-last)
    ("d" "Definition" symbol-overlay-jump-to-definition)
    ("e" "Mark" symbol-overlay-echo-mark)
    ("M" "MC Mark-All" symbol-overlay-mc-mark-all)	; from symbol-overlay-mc
    ]
   ["On Overlay"
    ("t" "Toggle Scope" symbol-overlay-toggle-in-scope)
    ("w" "Copy" symbol-overlay-save-symbol)
    ("r" "Rename" symbol-overlay-rename)
    ("q" "Query Replace" symbol-overlay-query-replace)
    ("s" "ISearch" symbol-overlay-isearch-literally)
    ("g" "Grep" rg-dwim)		; from rg.el
    ]
   ]
  )
(global-set-key (kbd "s-.") 'hrm-symbol-overlay-transient)

[vdm]

https://github.com/kickingvegas/casual-symbol-overlay