Add python-mongo template terraform

.gitignore

@@ -36,4 +36,8 @@ obj/
 bin/
 node_modules/
 test-results/
-playwright-report/
+
+# terraform .tfstate files
+**/.terraform
+*.tfstate*
+*.terraform*

.vscode/cspell.global.yaml

@@ -80,6 +80,10 @@ ignoreWords:
     - httptrigger
     - resourcegroups
     - devcontainer
+    - azurecaf
+    - azurerm
+    - aztfmod
+    - menuid
 useGitignore: true
 dictionaryDefinitions:
     - name: gitHubUserAliases

templates/common/infra/terraform/applicationinsights/applicationinsights_output.tf

@@ -0,0 +1,4 @@
+output "APPLICATIONINSIGHTS_CONNECTION_STRING" {
+  value     = azurerm_application_insights.applicationinsights.connection_string
+  sensitive = true
+}

templates/common/infra/terraform/applicationinsights/applicationinsights_variables.tf

@@ -0,0 +1,29 @@
+variable "location" {
+  description = "The supported azure location where the resource deployed"
+  type        = string
+}
+
+variable "rg_name" {
+  description = "The name of the resource group to deploy resources into"
+  type        = string
+}
+
+variable "environment_name" {
+  description = "The name of the environment to be deployed"
+  type        = string
+}
+
+variable "workspace_id" {
+  description = "The name of the Azure log analytics workspace"
+  type        = string
+}
+
+variable "tags" {
+  description = "A list of tags used for deployed services."
+  type        = map(string)
+}
+
+variable "resource_token" {
+  description = "A postfix string to centrally mitigate resource name collisions."
+  type        = string
+}

templates/todo/projects/python-mongo/.repo/terraform/azure.yaml

@@ -0,0 +1,15 @@
+# yaml-language-server: $schema=https://raw.githubusercontent.com/Azure/azure-dev/main/schemas/v1.0/azure.yaml.json
+
+name: todo-python-mongo-terraform
+metadata:
+  template: todo-python-mongo-terraform@0.0.1-beta
+services:
+  web:
+    project: ../../web/react-fluent
+    dist: build
+    language: js
+    host: appservice
+  api:
+    project: ../../api/python
+    language: py
+    host: appservice

templates/todo/projects/python-mongo/.repo/terraform/infra/apps.tf

@@ -0,0 +1,119 @@
+# ------------------------------------------------------------------------------------------------------
+# Deploy app service plan
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "plan_name" {
+  name          = random_string.resource_token.result
+  resource_type = "azurerm_app_service_plan"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_service_plan" "plan" {
+  name                = azurecaf_name.plan_name.result
+  location            = azurerm_resource_group.rg.location
+  resource_group_name = azurerm_resource_group.rg.name
+  os_type             = "Linux"
+  sku_name            = "B1"
+
+  tags = local.tags
+}
+
+# ------------------------------------------------------------------------------------------------------
+# Deploy app service web app
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "web_name" {
+  name          = "web-${random_string.resource_token.result}"
+  resource_type = "azurerm_app_service"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_linux_web_app" "web" {
+  name                = azurecaf_name.web_name.result
+  location            = azurerm_resource_group.rg.location
+  resource_group_name = azurerm_resource_group.rg.name
+  service_plan_id     = azurerm_service_plan.plan.id
+  https_only          = true
+  tags                = merge(local.tags, { azd-service-name : "web" })
+
+  site_config {
+    always_on        = true
+    ftps_state       = "FtpsOnly"
+    app_command_line = "pm2 serve /home/site/wwwroot --no-daemon --spa"
+    application_stack {
+      node_version = "16-lts"
+    }
+  }
+
+  app_settings = {
+    "SCM_DO_BUILD_DURING_DEPLOYMENT"        = "false"
+    "APPLICATIONINSIGHTS_CONNECTION_STRING" = module.applicationinsights.APPLICATIONINSIGHTS_CONNECTION_STRING
+  }
+
+  logs {
+    application_logs {
+      file_system_level = "Verbose"
+    }
+    detailed_error_messages = true
+    failed_request_tracing  = true
+    http_logs {
+      file_system {
+        retention_in_days = 1
+        retention_in_mb   = 35
+      }
+    }
+  }
+}
+
+# ------------------------------------------------------------------------------------------------------
+# Deploy app service api
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "appi_name" {
+  name          = "api-${random_string.resource_token.result}"
+  resource_type = "azurerm_app_service"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_linux_web_app" "api" {
+  name                = azurecaf_name.appi_name.result
+  location            = azurerm_resource_group.rg.location
+  resource_group_name = azurerm_resource_group.rg.name
+  service_plan_id     = azurerm_service_plan.plan.id
+  https_only          = true
+  tags                = merge(local.tags, { "azd-service-name" : "api" })
+
+  site_config {
+    always_on        = true
+    ftps_state       = "FtpsOnly"
+    app_command_line = local.api_command_line
+    application_stack {
+      python_version = "3.8"
+    }
+  }
+
+  identity {
+    type = "SystemAssigned"
+  }
+
+  app_settings = {
+    "AZURE_COSMOS_CONNECTION_STRING_KEY"    = "AZURE-COSMOS-CONNECTION-STRING"
+    "AZURE_COSMOS_DATABASE_NAME"            = azurerm_cosmosdb_mongo_database.mongodb.name
+    "SCM_DO_BUILD_DURING_DEPLOYMENT"        = "true"
+    "AZURE_KEY_VAULT_ENDPOINT"              = azurerm_key_vault.kv.vault_uri
+    "APPLICATIONINSIGHTS_CONNECTION_STRING" = module.applicationinsights.APPLICATIONINSIGHTS_CONNECTION_STRING
+  }
+  logs {
+    application_logs {
+      file_system_level = "Verbose"
+    }
+    detailed_error_messages = true
+    failed_request_tracing  = true
+    http_logs {
+      file_system {
+        retention_in_days = 1
+        retention_in_mb   = 35
+      }
+    }
+  }
+}

templates/todo/projects/python-mongo/.repo/terraform/infra/cosmos.tf

@@ -0,0 +1,71 @@
+# ------------------------------------------------------------------------------------------------------
+# Deploy cosmos db account
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "db_acc_name" {
+  name          = random_string.resource_token.result
+  resource_type = "azurerm_cosmosdb_account"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_cosmosdb_account" "db" {
+  name                            = azurecaf_name.db_acc_name.result
+  location                        = azurerm_resource_group.rg.location
+  resource_group_name             = azurerm_resource_group.rg.name
+  offer_type                      = "Standard"
+  kind                            = "MongoDB"
+  enable_automatic_failover       = false
+  enable_multiple_write_locations = false
+  mongo_server_version            = "4.0"
+  tags                            = local.tags
+
+  capabilities {
+    name = "EnableServerless"
+  }
+
+  consistency_policy {
+    consistency_level = "Session"
+  }
+
+  geo_location {
+    location          = azurerm_resource_group.rg.location
+    failover_priority = 0
+    zone_redundant    = false
+  }
+}
+
+# ------------------------------------------------------------------------------------------------------
+# Deploy cosmos mongo db and collections
+# ------------------------------------------------------------------------------------------------------
+resource "azurerm_cosmosdb_mongo_database" "mongodb" {
+  name                = "Todo"
+  resource_group_name = azurerm_cosmosdb_account.db.resource_group_name
+  account_name        = azurerm_cosmosdb_account.db.name
+}
+
+resource "azurerm_cosmosdb_mongo_collection" "todolist" {
+  name                = "TodoList"
+  resource_group_name = azurerm_cosmosdb_account.db.resource_group_name
+  account_name        = azurerm_cosmosdb_account.db.name
+  database_name       = azurerm_cosmosdb_mongo_database.mongodb.name
+  shard_key           = "_id"
+
+
+  index {
+    keys   = ["_id"]
+    unique = true
+  }
+}
+
+resource "azurerm_cosmosdb_mongo_collection" "todocollection" {
+  name                = "TodoItem"
+  resource_group_name = azurerm_cosmosdb_account.db.resource_group_name
+  account_name        = azurerm_cosmosdb_account.db.name
+  database_name       = azurerm_cosmosdb_mongo_database.mongodb.name
+  shard_key           = "_id"
+
+  index {
+    keys   = ["_id"]
+    unique = true
+  }
+}

templates/todo/projects/python-mongo/.repo/terraform/infra/keyvault.tf

@@ -0,0 +1,53 @@
+# ------------------------------------------------------------------------------------------------------
+# DEPLOY AZURE KEYVAULT
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "kv_name" {
+  name          = random_string.resource_token.result
+  resource_type = "azurerm_key_vault"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_key_vault" "kv" {
+  name                     = azurecaf_name.kv_name.result
+  location                 = azurerm_resource_group.rg.location
+  resource_group_name      = azurerm_resource_group.rg.name
+  tenant_id                = data.azurerm_client_config.current.tenant_id
+  purge_protection_enabled = false
+  sku_name                 = "standard"
+
+  tags = local.tags
+}
+
+resource "azurerm_key_vault_access_policy" "app" {
+  key_vault_id = azurerm_key_vault.kv.id
+  tenant_id    = data.azurerm_client_config.current.tenant_id
+  object_id    = azurerm_linux_web_app.api.identity.0.principal_id
+
+  secret_permissions = [
+    "Get",
+    "Set",
+    "List",
+    "Delete",
+  ]
+}
+
+resource "azurerm_key_vault_access_policy" "user" {
+  count        = var.principal_id == "" ? 0 : 1
+  key_vault_id = azurerm_key_vault.kv.id
+  tenant_id    = data.azurerm_client_config.current.tenant_id
+  object_id    = var.principal_id
+
+  secret_permissions = [
+    "Get",
+    "Set",
+    "List",
+    "Delete",
+  ]
+}
+
+resource "azurerm_key_vault_secret" "dbconnection" {
+  name         = "AZURE-COSMOS-CONNECTION-STRING"
+  value        = azurerm_cosmosdb_account.db.connection_strings[0]
+  key_vault_id = azurerm_key_vault.kv.id
+}

templates/todo/projects/python-mongo/.repo/terraform/infra/loganalytics.tf

@@ -0,0 +1,18 @@
+# ------------------------------------------------------------------------------------------------------
+# Deploy log analytics workspace
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "workspace_name" {
+  name          = random_string.resource_token.result
+  resource_type = "azurerm_log_analytics_workspace"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_log_analytics_workspace" "workspace" {
+  name                = azurecaf_name.workspace_name.result
+  location            = azurerm_resource_group.rg.location
+  resource_group_name = azurerm_resource_group.rg.name
+  sku                 = "PerGB2018"
+  retention_in_days   = 30
+  tags                = local.tags
+}

templates/todo/projects/python-mongo/.repo/terraform/infra/main.tf

@@ -0,0 +1,41 @@
+locals {
+  tags             = { azd-env-name : var.environment_name }
+  api_command_line = "gunicorn --workers 4 --threads 2 --timeout 60 --access-logfile \"-\" --error-logfile \"-\" --bind=0.0.0.0:8000 -k uvicorn.workers.UvicornWorker todo.app:app"
+}
+# ------------------------------------------------------------------------------------------------------
+# Deploy resource Group
+# ------------------------------------------------------------------------------------------------------
+resource "azurecaf_name" "rg_name" {
+  name          = var.environment_name
+  resource_type = "azurerm_resource_group"
+  random_length = 0
+  clean_input   = true
+}
+
+resource "azurerm_resource_group" "rg" {
+  name     = azurecaf_name.rg_name.result
+  location = var.location
+
+  tags = local.tags
+}
+
+resource "random_string" "resource_token" {
+  length  = 10
+  upper   = false
+  lower   = true
+  numeric = false
+  special = false
+}
+
+# ------------------------------------------------------------------------------------------------------
+# Deploy application insights
+# ------------------------------------------------------------------------------------------------------
+module "applicationinsights" {
+  source           = "../../../../../../common/infra/terraform/applicationinsights"
+  location         = var.location
+  rg_name          = azurerm_resource_group.rg.name
+  environment_name = var.environment_name
+  workspace_id     = azurerm_log_analytics_workspace.workspace.id
+  tags             = azurerm_resource_group.rg.tags
+  resource_token   = random_string.resource_token.result
+}

templates/todo/projects/python-mongo/.repo/terraform/infra/main.tfvars.json

@@ -0,0 +1,5 @@
+{
+    "location": "${AZURE_LOCATION}",
+    "environment_name": "${AZURE_ENV_NAME}",
+    "principal_id": "${AZURE_PRINCIPAL_ID}"
+}