Dragging - Corpse carrying and dragging - continued

addons/common/XEH_postInit.sqf

@@ -122,6 +122,11 @@
     _object setMass _mass;
 }] call CBA_fnc_addEventHandler;
 
+[QGVAR(awake), {
+    params ["_object", "_awake"];
+    _object awake _awake;
+}] call CBA_fnc_addEventHandler;
+
 [QGVAR(disableWeaponAssembly), {
     params ["_object", "_set"];
     _object enableWeaponDisassembly (_set < 1);

addons/dragging/CfgVehicles.hpp

@@ -3,6 +3,9 @@
 class CBA_Extended_EventHandlers;
 
 class CfgVehicles {
+    class C_man_1;
+    class GVAR(clone): C_man_1 {};
+
     // Static weapons
     class LandVehicle;
     class StaticWeapon: LandVehicle {

addons/dragging/XEH_PREP.hpp

@@ -5,8 +5,10 @@ PREP(canDrop_carry);
 PREP(canRun_carry);
 PREP(carryObject);
 PREP(carryObjectPFH);
+PREP(createClone);
 PREP(dragObject);
 PREP(dragObjectPFH);
+PREP(dropClone);
 PREP(dropObject);
 PREP(dropObject_carry);
 PREP(getWeight);

addons/dragging/XEH_postInit.sqf

@@ -20,6 +20,11 @@ if (isNil QGVAR(maxWeightCarryRun)) then {
     GVAR(maxWeightCarryRun) = 50;
 };
 
+// Extended EH doesn't fire for dead units, so add interactions manually
+{
+    _x call FUNC(initPerson);
+} forEach allDeadMen;
+
 ["isNotDragging", {!((_this select 0) getVariable [QGVAR(isDragging), false])}] call EFUNC(common,addCanInteractWithCondition);
 ["isNotCarrying", {!((_this select 0) getVariable [QGVAR(isCarrying), false])}] call EFUNC(common,addCanInteractWithCondition);
 
@@ -54,6 +59,14 @@ if (isNil QGVAR(maxWeightCarryRun)) then {
 // Handle waking up dragged unit and falling unconscious while dragging
 ["ace_unconscious", LINKFUNC(handleUnconscious)] call CBA_fnc_addEventHandler;
 
+// Handle local effect commands for clones
+[QGVAR(cloneCreated), {
+    params ["_unit", "_clone"];
+
+    _clone setFace face _unit;
+    _clone setMimic "unconscious";
+}] call CBA_fnc_addEventHandler;
+
 // Display event handler
 ["MouseZChanged", {(_this select 1) call FUNC(handleScrollWheel)}] call CBA_fnc_addDisplayHandler;
 

addons/dragging/functions/fnc_canCarry.sqf

@@ -18,7 +18,7 @@
 
 params ["_unit", "_target"];
 
-if !(alive _target && {_target getVariable [QGVAR(canCarry), false]} && {isNull objectParent _target}) exitWith {false};
+if !((alive _target || {_target isKindOf "CAManBase"}) && {_target getVariable [QGVAR(canCarry), false]} && {isNull objectParent _target}) exitWith {false};
 
 if !([_unit, _target, []] call EFUNC(common,canInteractWith)) exitWith {false};
 
@@ -35,7 +35,8 @@ if (_target isKindOf "StaticWeapon") exitWith {
 if (_target isKindOf "CAManBase") exitWith {
     isAwake _target && // not ragdolled
     {lifeState _target == "INCAPACITATED" ||
-    {_target getHitPointDamage "HitLegs" >= 0.5}}
+    {_target getHitPointDamage "HitLegs" >= 0.5} ||
+    {(animationState _target) in ["", "unconscious", "deadstate"]}}
 };
 
 // Check max items for WeaponHolders

addons/dragging/functions/fnc_canDrag.sqf

@@ -18,7 +18,7 @@
 
 params ["_unit", "_target"];
 
-if !(alive _target && {_target getVariable [QGVAR(canDrag), false]} && {isNull objectParent _target}) exitWith {false};
+if !((alive _target || {_target isKindOf "CAManBase"}) && {_target getVariable [QGVAR(canDrag), false]} && {isNull objectParent _target}) exitWith {false};
 
 if !([_unit, _target, ["isNotSwimming"]] call EFUNC(common,canInteractWith)) exitWith {false};
 
@@ -31,7 +31,8 @@ if (_target isKindOf "StaticWeapon") exitWith {
 if (_target isKindOf "CAManBase") exitWith {
     isAwake _target && // not ragdolled
     {lifeState _target == "INCAPACITATED" ||
-    {_target getHitPointDamage "HitLegs" >= 0.5}}
+    {_target getHitPointDamage "HitLegs" >= 0.5} ||
+    {(animationState _target) in ["", "unconscious", "deadstate"]}}
 };
 
 // Check max items for WeaponHolders

addons/dragging/functions/fnc_createClone.sqf

@@ -0,0 +1,65 @@
+#include "..\script_component.hpp"
+/*
+ * Author: BaerMitUmlaut, johnb43
+ * Creates a draggable / carryable clone of a dead unit.
+ *
+ * Arguments:
+ * 0: Dead unit <OBJECT>
+ *
+ * Return Value:
+ * Cloned unit <OBJECT>
+ *
+ * Example:
+ * [player] call ace_dragging_fnc_createClone;
+ *
+ * Public: No
+ */
+params ["_target"];
+
+// Get current position of unit, -10 m below surface
+private _posATL = getPosATL _target;
+_posATL set [2, -10];
+
+private _clone = createVehicle [QGVAR(clone), _posATL];
+
+// Clone loadout
+[_clone, _target call CBA_fnc_getLoadout] call CBA_fnc_setLoadout;
+
+// Hide unit until it can be moved below terrain
+private _isObjectHidden = isObjectHidden _target;
+
+if (_isObjectHidden) then {
+    [QEGVAR(common,hideObjectGlobal), [_target, true]] call CBA_fnc_serverEvent;
+};
+
+private _simulationEnabled = simulationEnabled _target;
+
+if (_simulationEnabled) then {
+    [QEGVAR(common,enableSimulationGlobal), [_target, false]] call CBA_fnc_serverEvent;
+};
+
+private _isInRemainsCollector = isInRemainsCollector _target;
+
+// Make sure corpse isn't deleted by engine's garbage collector
+if (_isInRemainsCollector) then {
+    removeFromRemainsCollector [_target];
+};
+
+// Disable all damage
+_clone allowDamage false;
+_clone setVariable [QGVAR(original), [_target, _isInRemainsCollector, _isObjectHidden, _simulationEnabled], true];
+
+// Turn on PhysX so that unit is not desync when moving with 'setPos' commands
+[QEGVAR(common,awake), [_target, true]] call CBA_fnc_globalEvent;
+
+[{
+    params ["_target", "_posATL"];
+
+    // Move unit below terrain in order to hide it
+    _target setPosATL _posATL;
+}, [_target, _posATL], 0.1] call CBA_fnc_waitAndExecute;
+
+// Sets the facial expression
+[[QGVAR(cloneCreated), [_target, _clone]] call CBA_fnc_globalEventJIP, _clone] call CBA_fnc_removeGlobalEventJIP;
+
+_clone

addons/dragging/functions/fnc_dropClone.sqf

@@ -0,0 +1,67 @@
+#include "..\script_component.hpp"
+/*
+ * Author: BaerMitUmlaut, johnb43
+ * Drops a draggable / carryable clone of a dead unit.
+ *
+ * Arguments:
+ * 0: Unit dragging / carrying <OBJECT>
+ * 1: Clone <OBJECT>
+ * 2: If unit is in building <BOOL>
+ *
+ * Return Value:
+ * Original unit <OBJECT>
+ *
+ * Example:
+ * [player, cursorObject, false] call ace_dragging_fnc_dropClone;
+ *
+ * Public: No
+ */
+params ["_unit", "_clone", "_inBuilding"];
+
+(_clone getVariable [QGVAR(original), []]) params [["_target", objNull], ["_isInRemainsCollector", true], ["_isObjectHidden", false], ["_simulationEnabled", true]];
+
+// Check if unit was deleted
+if (!isNull _target) then {
+    // Turn on PhysX so that unit is not desync when moving
+    [QEGVAR(common,awake), [_target, true]] call CBA_fnc_globalEvent;
+
+    private _posASL = getPosASL _clone;
+
+    if (_inBuilding) then {
+        _posASL = _posASL vectorAdd [0, 0, 0.05];
+    };
+
+    // Set the unit's direction
+    [QEGVAR(common,setDir), [_target, getDir _unit + 180], _target] call CBA_fnc_targetEvent;
+
+    [{
+        params ["_target", "_clone", "_isObjectHidden", "_simulationEnabled", "_posASL"];
+
+        // Bring unit back to clone's position
+        _target setPosASL _posASL;
+
+        [{
+            params ["_target", "_clone", "_isObjectHidden", "_simulationEnabled"];
+
+            if (_isObjectHidden) then {
+                [QEGVAR(common,hideObjectGlobal), [_target, false]] call CBA_fnc_serverEvent;
+            };
+
+            if (_simulationEnabled) then {
+                [QEGVAR(common,enableSimulationGlobal), [_target, true]] call CBA_fnc_serverEvent;
+            };
+
+            deleteVehicle _clone;
+        }, _this, 0.1] call CBA_fnc_waitAndExecute;
+    }, [_target, _clone, _isObjectHidden, _simulationEnabled, _posASL], 0.1] call CBA_fnc_waitAndExecute;
+
+    if (_isInRemainsCollector) then {
+        addToRemainsCollector [_target];
+    };
+};
+
+// Detach first to prevent objNull in attachedObjects
+detach _clone;
+deleteVehicle _clone;
+
+_target

addons/dragging/functions/fnc_dropObject.sqf

@@ -31,6 +31,12 @@ if !(GVAR(dragAndFire)) then {
 };
 
 private _inBuilding = _unit call FUNC(isObjectOnObject);
+private _isClone = _target isKindOf QGVAR(clone);
+
+// Drop cloned dead units
+if (_isClone) then {
+    _target = [_unit, _target, _inBuilding] call FUNC(dropClone);
+};
 
 // Play release animation
 if !(_unit getVariable ["ACE_isUnconscious", false]) then {
@@ -57,7 +63,7 @@ _unit removeWeapon "ACE_FakePrimaryWeapon";
 [_unit, "blockThrow", QUOTE(ADDON), false] call EFUNC(common,statusEffect_set);
 
 // Prevent object from flipping inside buildings
-if (_inBuilding) then {
+if (_inBuilding && {!_isClone}) then {
     _target setPosASL (getPosASL _target vectorAdd [0, 0, 0.05]);
     TRACE_2("setPos",getPosASL _unit,getPosASL _target);
 };

addons/dragging/functions/fnc_dropObject_carry.sqf

@@ -25,6 +25,12 @@ TRACE_1("params",_this);
 _unit setVariable [QGVAR(releaseActionID), nil];
 
 private _inBuilding = _unit call FUNC(isObjectOnObject);
+private _isClone = _target isKindOf QGVAR(clone);
+
+// Drop cloned dead units
+if (_isClone) then {
+    _target = [_unit, _target, _inBuilding] call FUNC(dropClone);
+};
 
 // Prevent collision damage
 [QEGVAR(common,fixCollision), _unit] call CBA_fnc_localEvent;
@@ -71,8 +77,9 @@ if (_previousWeaponIndex != -1) then {
 [_unit, "blockThrow", QUOTE(ADDON), false] call EFUNC(common,statusEffect_set);
 
 // Prevent object from flipping inside buildings
-if (_inBuilding) then {
+if (_inBuilding && {!_isClone}) then {
     _target setPosASL (getPosASL _target vectorAdd [0, 0, 0.05]);
+    TRACE_2("setPos",getPosASL _unit,getPosASL _target);
 };
 
 _unit setVariable [QGVAR(isCarrying), false, true];

addons/dragging/functions/fnc_handleAnimChanged.sqf

@@ -5,7 +5,7 @@
  *
  * Arguments:
  * 0: Unit <OBJECT>
- * 1: Animaion <STRING>
+ * 1: Animation <STRING>
  *
  * Return Value:
  * None

addons/dragging/functions/fnc_startCarry.sqf

@@ -35,6 +35,11 @@ private _timer = CBA_missionTime + 5;
 
 // Handle objects vs. persons
 if (_target isKindOf "CAManBase") then {
+    // Create clone for dead units
+    if (!alive _target) then {
+        _target = _target call FUNC(createClone);
+    };
+
     private _primaryWeapon = primaryWeapon _unit;
 
     // Add a primary weapon if the unit has none

addons/dragging/functions/fnc_startDrag.sqf

@@ -31,6 +31,11 @@ if (_weight > GETMVAR(ACE_maxWeightDrag,1E11)) exitWith {
     [LLSTRING(UnableToDrag)] call EFUNC(common,displayTextStructured);
 };
 
+// Create clone for dead units
+if (!alive _target) then {
+    _target = _target call FUNC(createClone);
+};
+
 private _primaryWeapon = primaryWeapon _unit;
 
 // Add a primary weapon if the unit has none