Using stable and unstable channels with flakes

[timsofteng]

Hello. Can you help me please with multi channels issue?
I want to use packages from stable and unstable bracnches in home manager.
I'm using flakes.
How can i do it? What i need to add to my flake.nix and how I can use it inside home-manager?

Here is my flake.nix config:

`{
inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09";
inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

inputs.home-manager.url = "github:nix-community/home-manager/master";
inputs.home-manager.inputs.nixpkgs.follows = "/nixpkgs";

outputs = inputs: {

nixosConfigurations.nixos = inputs.nixpkgs.lib.nixosSystem {
  system = "x86_64-linux";
  # Things in this set are passed to modules and accessible
  # in the top-level arguments (e.g. `{ pkgs, lib, inputs, ... }:`).
  specialArgs = {
    inherit inputs;
  };
  modules = [
    inputs.home-manager.nixosModules.home-manager

    ({ pkgs, ... }: {
      nix.extraOptions = "experimental-features = nix-command flakes";
      nix.package = pkgs.nixFlakes;
      nix.registry.nixpkgs.flake = inputs.nixpkgs;
      
      home-manager.useGlobalPkgs = true;

    })

    ./configuration.nix
  ];
};

};
}`

[jkachmar]

I don't necessarily know that this is something home-manager specifically concerns itself with, but I'm currently using overlays as a way to "inject" alternative package sets.

e.g. The following is an excerpt from my inputs attrset:

{
  inputs = {
    # Stable NixOS nixpkgs package set; pinned to the 20.03 release.
    nixosPkgs.url = "github:nixos/nixpkgs-channels/nixos-20.03-small";
    # Stable Darwin nixpkgs package set; pinned to the 20.03 release.
    darwinPkgs.url = "github:nixos/nixpkgs-channels/nixpkgs-20.03-darwin";
    # Tracks nixos/nixpkgs-channels unstable branch.
    #
    # Try to pull new/updated packages from 'unstable' whenever possible, as
    # these will likely have cached results from the last successful Hydra
    # jobset.
    unstable.url = "github:nixos/nixpkgs-channels/nixos-unstable";
    # Tracks nixos/nixpkgs main branch.
    #
    # Only pull from 'trunk' when channels are blocked by a Hydra jobset
    # failure or the 'unstable' channel has not otherwise updated recently for
    # some other reason.
    trunk.url = "github:nixos/nixpkgs";
  };
  # Remaining attrs elided.
}

...and the following is an excerpt from my outputs attrset:

{
  # ...
  outputs = inputs@{ self, darwinPkgs, nixosPkgs, ... }: {
    overlays = {
      # Inject 'unstable' and 'trunk' into the overridden package set, so that
      # the following overlays may access them (along with any system configs
      # that wish to do so).
      pkg-sets = (
        final: prev: {
          unstable = import inputs.unstable { system = final.system; };
          trunk = import inputs.trunk { system = final.system; };
        }
      );
    # Remaining attributes elided.
    };
}

This lets me reference unstable and trunk in overlays like so:

final: prev: {
  emacsMacport = final.unstable.emacsMacport;
}

...and in the main package set as follows:

{ pkgs, ... }:
{
  environment.systemPackages = with pkgs; [ unstable.git ];
}

---

What I'm doing is pulling the system value out of the final configuration (which avoids using something like builtins.currentSystem, keeping everything pure), and then using that as the bare-minimum of what's required to instantiate a nixpkgs package set (other config stuff like allowUnfree could also be applied here).

This means I can easily reference stuff from any number of additional nixpkgs package sets anywhere in my configuration.

The somewhat-less-than-obvious drawback is that it seems to slow down evaluation (presumably this is some fixpoint nonsense) to something like 38s for my configuration, so take care about that.

EDIT: Eh, maybe it's something about my computer or configuration in particular; I tried it without the overlay going through the fixed point and seems to still take about 30s to evaluate the config so maybe I don't know what I'm talking about.

[jkachmar]

I just noticed specialArgs in your excerpt; I don't know too much about specialArgs in particular, but if you don't need access to these package sets in your overlays (or if you're not using overlays at all), it might be more direct to do something like:

{
  nixosConfigurations.nixos = inputs.nixpkgs.lib.nixosSystem {
    system = "x86_64-linux";
    modules =
      let
        defaults = { pkgs, ... }: {
          _module.args.nixpkgs-unstable = import inputs.nixpkgs-unstable { inherit (pkgs.stdenv.targetPlatform) system; };
        };
      in [
        defaults
        inputs.home-manager.nixosModules.home-manager
        # Remaining modules elided.
      ];
};

...which should allow you to access inputs as follows from any modules imported after the _module.args.inputs line like this:

{ pkgs, nixpkgs-unstable, ... }:
{
  environment.systemPackages = [ nixpkgs-unstable.git ];
}

[berbiche]

To complement what @jkachmar said, you would need to inject your inputs within home-manager otherwise you would need to use an overlay.

{
  nixosConfigurations.nixos = inputs.nixpkgs.lib.nixosSystem {
    system = "x86_64-linux";
    modules = [
      inputs.home-manager.nixosModules.home-manager
      ({ ... }: {
        home-manager.users.your-user = { ... }: {
          _module.args.inputs = inputs;
        };
      })
    ];
  };
}

Your inputs would the be available as a module's arguments:

{ pkgs, inputs, ... }:

{
  # Note, `${pkgs.system}` is the "architecture" of the machine evaluating and building
  environment.systemPackages = with inputs.nixpkgs-unstable.legacyPackages.${pkgs.system}; [  ];
}

The logic remains valid if you are using home-manager outside of NixOS. You would need to inject the inputs through _module.args.

[teto]

Question looks answered, please reopen if not.

[badly-drawn-wizards]

Hi, I'm trying to use _module.args, but failing miserably.

Here is the NixOS module with inputs provided through specialArgs

{ inputs, ... }:
{
  imports = [
    inputs.home-manager.nixosModules.home-manager
  ];

  home-manager.useGlobalPkgs = true;
  home-manager.useUserPackages = true;
  home-manager.users.reuben = {
    imports = [
      {
        _module.args.inputs = inputs;
      }
      ./home-manager.nix
    ];
  };
}

I'm getting infinite recursion whenever I force inputs as an argument in a home-manager module

[berbiche]

AFAIK, an import must either be a function or a path. I think Nix is recursing into the attribute set and tries to import all inputs which causes an infinite recursion error.

IIRC this should work:

{
  home-manager.users.your-user = {
    imports = [ ./home.nix ];
    _module.args.inputs = inputs;
  };
}

or

{
  home-manager.users.your-user = {
    imports = [
      ({ ... }: { _module.args.inputs = inputs; })
      ./home.nix
    ];
  };
}

[badly-drawn-wizards]

It's seems either one gives the same result unfortunately. May be a different cause though. I'm just going to try the overlay route.

[berbiche]

@badly-drawn-wizards can you open a new issue with the configuration you are making it work with?

[badly-drawn-wizards]

@berbiche Will do

[stites]

I am trying to replicate this original question but am running into some problems. Notably, in the original question I would like to have the same inputs:

inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09";
inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

inputs.home-manager.url = "github:nix-community/home-manager/master";
inputs.home-manager.inputs.nixpkgs.follows = "/nixpkgs-unstable";

(note that hm-master follows nixpkgs-unstable here)

I am able to use _module.args and specialArgs as suggested, but only when I have home-manager pinned to 20.09. Whenever i follow master, compiling flakes fails (specifically because of a types.anything in matplotlib).

I've tried to "swap out" with _module.args.pkgs = unstablePkgs; before loading the hm-module, but this doesn't seem to work. Would anyone have suggestions for this?

[berbiche]

@stites do you have home.stateVersion = "20.09"? Important changes were done in 20.09 regarding loading nixpkgs

[stites]

yes, I do have home.stateVersion = "20.09". Another thing I just tried was to set:

  home-manager.useGlobalPkgs = false;
  home-manager.useUserPackages = true;

with the above flake inputs. this also produces an error with the missing types.anything -- it's not clear to me where the input is going since there are no listed inputs for nixpkgs in the flake (sorry, also a flake noob here, so maybe nixpkgs is always implied?).

[berbiche]

inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09";
inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";

inputs.home-manager.url = "github:nix-community/home-manager/master";
inputs.home-manager.inputs.nixpkgs.follows = "/nixpkgs-unstable";

The nixpkgs.follows = "/nixpkgs-unstable" has a leading "/" (error while copy-pasting?)

Home Manager doesn't have it's own flake.lock, so the nixpkgs revision it uses is not pinned, it will be pinned the first time you evaluate the flake.

What is the output of nix flake list-inputs?

it's not clear to me where the input is going since there are no listed inputs for nixpkgs in the flake

There's a set of default flake inputs, it has something to do with a registry but I'm not really confident about my knowledge in that regard.
More information is available here: https://github.com/NixOS/nix/blob/a93916b1905cd7b968e92cd94a3e4a595bff2e0f/src/nix/registry.md