Fire - Mini-Rewrite

addons/compat_sog/functions/fnc_woundsHandlerIncendiary.sqf

@@ -18,8 +18,6 @@
  * Public: No
  */
 
-#define BURN_THRESHOLD 1
-
 params ["_unit", "_damages"];
 TRACE_2("woundsHandlerIncendiary",_unit,_damages);
 
@@ -32,9 +30,7 @@ private _fireDamage = 0;
 private _intensity = linearConversion [0, 20, _fireDamage, 0, 10, true];
 TRACE_2("",_intensity,_fireDamage);
 
-if (_intensity > BURN_THRESHOLD) then {
-    TRACE_2("Setting unit ablaze",_intensity,BURN_THRESHOLD);
-    ["ace_fire_burn", [_unit, _intensity]] call CBA_fnc_globalEvent;
-};
+// Let fire handle if unit is set ablaze or not
+[QEGVAR(fire,burn), [_unit, _intensity]] call CBA_fnc_localEvent;
 
 _this // return

addons/compat_spe/functions/fnc_woundsHandlerIncendiary.sqf

@@ -18,8 +18,6 @@
  * Public: No
  */
 
-#define BURN_THRESHOLD 1
-
 params ["_unit", "_damages"];
 TRACE_2("woundsHandlerIncendiary",_unit,_damages);
 
@@ -32,9 +30,7 @@ private _fireDamage = 0;
 private _intensity = linearConversion [0, 20, _fireDamage, 0, 10, true];
 TRACE_2("",_intensity,_fireDamage);
 
-if (_intensity > BURN_THRESHOLD) then {
-    TRACE_2("Setting unit ablaze",_intensity,BURN_THRESHOLD);
-    ["ace_fire_burn", [_unit, _intensity]] call CBA_fnc_globalEvent;
-};
+// Let fire handle if unit is set ablaze or not
+[QEGVAR(fire,burn), [_unit, _intensity]] call CBA_fnc_localEvent;
 
 _this // return

addons/cookoff/functions/fnc_cookOffServer.sqf

@@ -175,7 +175,7 @@ if (_delayBetweenSmokeAndFire) then {
             if (["ace_fire"] call EFUNC(common,isModLoaded)) then {
                 // Use current intensity, in case GVAR(cookoffDuration) is very large and only 1 flameout stage happens
                 {
-                    [QEGVAR(fire,burn), [_x, _intensity * 1.5, _instigator]] call CBA_fnc_globalEvent;
+                    [QEGVAR(fire,burn), [_x, _intensity * 1.5, _instigator], _x] call CBA_fnc_targetEvent;
                 } forEach (crew _vehicle);
             };
 

addons/fire/CfgSounds.hpp

@@ -1,10 +1,10 @@
 // weird ass concatenation syntax. PBO Project complains otherwise...
 #define CONCAT(a,b) a####b
 #define CREATE_SCREAM(no)\
-class GVAR(DOUBLES(scream,no)) { \
-    name = QUOTE(GVAR(CONCAT(scream,no)));\
-    sound[] = {QUOTE(PATHTOF(CONCAT(sounds\scream,no).ogg)), QUOTE(db+8), 1};\
-    titles[] = {}; \
+class GVAR(DOUBLES(scream,no)) {\
+    name = QGVAR(CONCAT(scream,no));\
+    sound[] = {QPATHTOF(CONCAT(sounds\scream,no).ogg), QUOTE(db+8), 1};\
+    titles[] = {};\
 }
 
 class CfgSounds {

addons/fire/CfgVehicles.hpp

@@ -0,0 +1,7 @@
+class CfgVehicles {
+    class Static;
+    class GVAR(logic): Static {
+        scope = 1;
+        displayName = "";
+    };
+};

addons/fire/XEH_PREP.hpp

@@ -1,9 +1,10 @@
 PREP(burn);
-PREP(isBurning);
+PREP(burnEffects);
 PREP(burnIndicator);
 PREP(burnReaction);
+PREP(burnSimulation);
 PREP(fireManagerPFH);
-
+PREP(isBurning);
+PREP(medical_canPatDown);
 PREP(medical_progress);
 PREP(medical_success);
-PREP(medical_canPatDown);

addons/fire/XEH_postInit.sqf

@@ -1,37 +1,89 @@
 #include "script_component.hpp"
 
 [QGVAR(burn), LINKFUNC(burn)] call CBA_fnc_addEventHandler;
+[QGVAR(burnEffects), LINKFUNC(burnEffects)] call CBA_fnc_addEventHandler;
+[QGVAR(burnSimulation), LINKFUNC(burnSimulation)] call CBA_fnc_addEventHandler;
+
 [QGVAR(playScream), {
     params ["_scream", "_source"];
-    // only play sound if enabled in settings and enabled for the unit
+
+    // Only play sound if enabled in settings and enabled for the unit
     if (GVAR(enableScreams) && {_source getVariable [QGVAR(enableScreams), true]}) then {
         _source say3D _scream;
     };
 }] call CBA_fnc_addEventHandler;
 
-["ace_settingsInitialized", {
+if (!isServer) exitWith {};
+
+["CBA_settingsInitialized", {
     TRACE_1("settingsInit",GVAR(enabled));
+
     if (!GVAR(enabled)) exitWith {};
 
-    if (isServer) then {
-        [QGVAR(addFireSource), {
-            params ["_source", "_radius", "_intensity", "_key", ["_condition", { true }], ["_conditionArgs", []]];
-            private _fireLogic = createVehicle ["ACE_LogicDummy", [0, 0, 0], [], 0, "NONE"];
-            if (_source isEqualType objNull) then {
-                _fireLogic attachTo [_source];
-            } else {
-                _fireLogic setPosASL _source;
-            };
-
-            [GVAR(fireSources), _key, [_fireLogic, _radius, _intensity, _condition, _conditionArgs]] call CBA_fnc_hashSet;
-        }] call CBA_fnc_addEventHandler;
-
-        [QGVAR(removeFireSource), {
-            params ["_key"];
-            [GVAR(fireSources), _key] call CBA_fnc_hashRem;
-        }] call CBA_fnc_addEventHandler;
-
-        [LINKFUNC(fireManagerPFH), FIRE_MANAGER_PFH_DELAY, []] call CBA_fnc_addPerFrameHandler;
-        GVAR(fireSources) = [[], nil] call CBA_fnc_hashCreate;
-    };
+    GVAR(fireSources) = createHashMap;
+
+    [QGVAR(addFireSource), {
+        params [
+            ["_source", objNull, [objNull, []]],
+            ["_radius", 0, [0]],
+            ["_intensity", 0, [0]],
+            ["_key", ""],
+            ["_condition", {true}, [{}]],
+            ["_conditionArgs", []]
+        ];
+
+        private _isObject = _source isEqualType objNull;
+
+        // Check if the source is valid
+        if !(_isObject || {_source isEqualTypeParams [0, 0, 0]}) exitWith {};
+
+        if (_isObject && {isNull _source}) exitWith {};
+        if (_radius == 0 || _intensity == 0) exitWith {};
+        if (_key isEqualTo "") exitWith {}; // key can be many types
+
+        // hashValue supports more types than hashmaps do by default, but not all (e.g. locations)
+        private _hashedKey = hashValue _key;
+
+        if (isNil "_hashedKey") exitWith {
+            ERROR_2("Unsupported key type used: %1 - %2",_key,typeName _key);
+        };
+
+        // If a position is passed, create a static object at said position
+        private _sourcePos = if (_isObject) then {
+            getPosATL _source
+        } else {
+            ASLToATL _source
+        };
+
+        private _fireLogic = createVehicle [QGVAR(logic), _sourcePos, [], 0, "CAN_COLLIDE"];
+
+        // If an object was passed, attach logic to the object
+        if (_isObject) then {
+            _fireLogic attachTo [_source];
+        };
+
+        // To avoid issues, remove existing entries first before overwriting
+        if (_hashedKey in GVAR(fireSources)) then {
+            [QGVAR(removeFireSource), _key] call CBA_fnc_localEvent;
+        };
+
+        GVAR(fireSources) set [_hashedKey, [_fireLogic, _radius, _intensity, _condition, _conditionArgs]];
+    }] call CBA_fnc_addEventHandler;
+
+    [QGVAR(removeFireSource), {
+        params ["_key"];
+
+        private _hashedKey = hashValue _key;
+
+        if (isNil "_hashedKey") exitWith {
+            ERROR_2("Unsupported key type used: %1 - %2",_key,typeName _key);
+        };
+
+        (GVAR(fireSources) deleteAt _hashedKey) params [["_fireLogic", objNull]];
+
+        detach _fireLogic;
+        deleteVehicle _fireLogic;
+    }] call CBA_fnc_addEventHandler;
+
+    [LINKFUNC(fireManagerPFH), FIRE_MANAGER_PFH_DELAY, []] call CBA_fnc_addPerFrameHandler;
 }] call CBA_fnc_addEventHandler;

addons/fire/config.cpp

@@ -24,6 +24,7 @@ class CfgPatches {
 
 #include "CfgEventHandlers.hpp"
 #include "CfgSounds.hpp"
+#include "CfgVehicles.hpp"
 #include "ACE_Medical_Treatment_Actions.hpp"
 #include "RscTitles.hpp"